在 MS Word 中的“另存为”事件后更新所有字段？

Question

我正在创建一个文档模板，该模板最终将用作客户某些 Excel 数据的目的地。这将面向客户并由我以外的其他用户处理，因此我需要一个自动化的解决方案。

我正在使用 MS Word 的 CreateDate 字段来标记文档的创建日期。这只会在使用模板创建文档时触发，并且在“另存为”之后重命名基于模板构建的文档。但是，您必须在使用新文件名保存后手动更新域代码。

我是 VBA 的业余爱好者，但有以下代码来更新字段（来自 Greg Maxey）：

Public Sub UpdateAllFields()
  Dim rngStory As Word.Range
  Dim lngJunk As Long
  Dim oShp As Shape
  lngJunk = ActiveDocument.Sections(1).Headers(1).Range.StoryType
  For Each rngStory In ActiveDocument.StoryRanges
    'Iterate through all linked stories
    Do
      On Error Resume Next
      rngStory.Fields.Update
      Select Case rngStory.StoryType
        Case 6, 7, 8, 9, 10, 11
          If rngStory.ShapeRange.Count > 0 Then
            For Each oShp In rngStory.ShapeRange
              If oShp.TextFrame.HasText Then
                oShp.TextFrame.TextRange.Fields.Update
              End If
            Next
          End If
        Case Else
          'Do Nothing
        End Select
        On Error GoTo 0
        'Get next linked story (if any)
        Set rngStory = rngStory.NextStoryRange
      Loop Until rngStory Is Nothing
    Next
End Sub

我知道 BeforeSave 事件，但 Word 没有“保存后”事件，我不知道如何触发代码。有人帮忙吗？

Answer 1

您可以通过将命令名称重新用作宏来连接到许多 Word 菜单命令。最简单的方法是执行以下步骤：

1. 在 Word 中，选择开发人员>宏。
2. 将 Macros in 下拉菜单设置为 Word 命令。
3. 在命令列表中，选择FileSaveAs。
4. 将宏输入切换回宏所在的模板。
5. 点击创建按钮。 Word 在您的模板中创建一个仅包含以下行的新宏：

Dialogs(wdDialogFileSaveAs).Show

在该命令之后添加保存后需要运行的命令。

然后当用户进行另存为时，他们会看到对话框并保存文件，然后您的 VBA 就会运行。

一旦你有了想法，你就不必经历整个过程。只要您知道内置对话框和 Word 命令的 VBA 名称，就可以使用相同的模式输入它们。