批处理文件：“未定义环境变量”

Question

我正在使用一个调用外部批处理文件并传入命令数组的 Java 程序。我在批处理文件中有一个如下所示的循环：

set paramCount=0
for %%x in (%*) do (
    set /A paramCount+=1
    set list[!paramCount!]=%%x
)

参数是一堆目录，存储为字符串，像这样：

String[] commands = {"cmd.exe",
                     "/C",
                     "C:\Users\user\Documents", 
                     "C:\Users\user\Pictures", 
                     "C:\Users\user\Videos"}

如您所见，我的 for 循环应该遍历传递给批处理文件 (%*) 的参数列表并在脚本中模拟一个数组（因为命令数组中的前两个元素用于启动命令进程，只留下要循环的目录）。该程序一直运行良好，直到前几天我突然开始收到一条错误消息：

Environment variable list[ not defined

我根本没有对批处理文件进行任何更改，它似乎无缘无故停止工作。如果有必要的信息，我正在使用流程构建器来运行流程：

ProcessBuilder pb = new ProcessBuilder(commands);
Process p = pb.start();

据说在批处理文件中对数组使用这种语法是可以的，所以我不确定它为什么不接受它。感谢您在此问题上提供的任何帮助。我在使用这个程序时遇到了很多障碍，虽然我已经能够解决其中的 90%，但剩下的 10% 已经开始让我发疯了！谢谢！

编辑： 我重新编写了循环并添加了一些回显命令以使调试更容易。但是，当我运行批处理文件时，由于回显，没有任何内容打印到屏幕上，但我仍然收到相同的错误：

@echo off
setlocal enableDelayedExpansion
set paramCount=0
for %%x in (%*) do (
    echo !paramCount!
    echo %%x
    set list[!paramCount!]=%%x
    set /A paramCount=paramCount+1
)

我还忘了提到当我从 Eclipse 运行 Java 时程序运行良好；它正确调用批处理文件，并且一切都按预期工作。在我将项目导出到可运行的 JAR 并尝试运行它之前，我不会收到错误消息。

编辑 2：

在再次查看我的批处理文件代码后（我之前写过），我发现只有一行看起来可能会导致这个问题。奇怪的是，我使用了在其他地方找到的几乎相同的代码示例来对其进行建模，并且它工作了很长时间而没有给出错误。这是一个循环，旨在循环遍历在第一个循环中创建的列表“数组”的元素：

for /F "tokens=2 delims==" %%d in ('set list[') do (
    set /A paramCount+=1
    set _dir=%%d
    set _dir=!_dir:"=!
    if NOT "%%d"=="nul" set "dirs[!paramCount!]=!_dir!"
)

如您所见，第一行有一段写着set list[，我觉得这很奇怪。但是，正如我所提到的，它在很长一段时间内都运行良好。

Answer 1

我在 cmets 中提到了它，但我想我会为其他想知道的人发布一个答案：

如前所述，程序在 Eclipse 中运行良好，批处理文件被调用并按预期运行。但是，在对批处理文件进行一些更改之前，我已经从它们创建了 .exe，并且显然正在运行 .exe 而不是 .bat。这是我的一个非常愚蠢的错误，问题是由先前版本的批处理文件中的一些错误引起的。如果我没记错的话，那个错误是因为“数组元素”是空的。因此，我最终在对其进行操作之前进行了检查以确保它不是空的。以下是我目前正在使用的代码，它按预期工作：

@echo off
setlocal ENABLEDELAYEDEXPANSION
set /A paramCount=-3
for %%x in (%*) do (
    set list[!paramCount!]=%%x
    set /A paramCount=paramCount+1
)
set argA=%list[-3]%
set argB=%list[-2]%
set argC=%list[-1]%
for /F "tokens=2 delims==" %%a in ('set list[-') do SET "%%a="
set list[-3]=""
set list[-2]=""
set list[-1]=""
set paramCount=0
for /F "tokens=2 delims==" %%d in ('set list[') do (
    if not "%%d"=="" (
        set _dir=%%d
        set _dir=!_dir:"=!
        if NOT "%%d"=="nul" set "dirs[!paramCount!]=!_dir!" 
    ) 
    set /A paramCount+=1 )

谢谢大家的回答！

Answer 2

您发布的代码无法给出该错误消息。您的脚本中一定还有其他代码会导致该错误。

只有没有= 的 SET 语句可能会给出该错误。解析和扩展后，违规语句必须如下所示：

set list[
set "list[
set "list["

实际上，如果引号放错了位置，您可能会在出现= 的情况下收到该错误。例如，以下将给出该错误，因为最后一个 " 之后的所有文本都被忽略：

set "list["1]=value

1]=value 出现在最后一个 " 之后并被忽略，留下 set "list["。

您可能会考虑启用 ECHO，以便准确定位错误消息发生的位置。然后你需要弄清楚什么条件会导致那个时候的错误。

---

更新以响应有问题的“编辑 2：”

新发布的代码中的那个 IN() 子句几乎肯定是生成错误消息的地方。表示执行 FOR /F 循环时未定义列表“数组”。问题是，为什么不呢？要寻找的东西：

• 是否有什么东西阻止了之前定义列表“数组”的 FOR 循环的运行？

• 您确定将参数正确传递给脚本吗？如果没有参数，那么就不会有数组。

• 在第二个 FOR 循环有机会执行之前，是否有未定义的数组？

我建议你加入一些诊断 ECHO 语句来帮助调试。例如，ECHO BEFORE 1ST LOOP 紧接在定义数组的循环之前，以确保到达循环。或者 ECHO ARGS = %* 在脚本的开头确保参数被正确传递。快乐的侦探:-)

Answer 3

我尝试了下面的代码，从命令行调用时它对我有用。

@echo off
setlocal enabledelayedexpansion

set paramCount=0

for %%x in (%*) do (
    set /A paramCount=!paramCount!+1
    set list[!paramCount!]=%%x
)
echo !list[1]!
echo !list[2]!
echo !list[3]!