在 Perl 中，while 循环通常比 for 循环快吗？

Question

我做了一个小实验，如下所示，在 Perl 中，while 循环似乎比 for 循环快。但是由于实验相当粗糙，而且主题可能比看起来要复杂得多，所以我想听听您对此有何看法。 一如既往地感谢任何 cmets/建议 :)

在以下两个小脚本中，我分别尝试了 while 和 for 循环来计算 100,000 的阶乘。有 while 循环的那个用了 57 分 17 秒完成，而 for 循环等价的用了 1 小时 7 分 54 秒。

有while循环的脚本：

use strict;
use warnings;
use bigint;

my $now = time;

my $n = shift;
my $s = 1;

while(1){
$s *= $n;
$n--;
last if $n==2;
}

print $s*$n;
$now = time - $now;
printf("\n\nTotal running time: %02d:%02d:%02d\n\n", int($now / 3600),
            int(($now % 3600) / 60), int($now % 60));

具有 for 循环的脚本：

use strict;
use warnings;
use bigint;

my $now = time;

my $n =shift;
my $s=1;

for (my $i=2; $i<=$n;$i++) {
$s = $s*$i;
}

print $s;
$now = time - $now;
printf("\n\nTotal running time: %02d:%02d:%02d\n\n", int($now / 3600),
            int(($now % 3600) / 60), int($now % 60));

Answer 1

如果 while 和 for 循环之间实际上有任何“真正的”区别，我会感到震惊。假设它们在做“完全相同”的事情，解释器应该对它们进行优化，使其或多或少相同。

我敢打赌，区别可能只是在两次执行期间其他进程争夺资源的方式不同。

即使有区别，也不要被The Sad Tragedy of Micro-Optimization Theater 所困扰。

Answer 2

循环不等效，您主要是在破坏 bigint 包，它与 for 与 while 本身无关。

while 循环使用符号“$s *= $i”，但 for 循环使用“$s = $s * $i”。 很容易证明它们并不相同。此外，一个循环计数；另一个倒计时。这会影响要相乘的数字有多大。这是二阶效应 - 但并非完全可以忽略。

[更新：修改为仅显示一个版本的代码，时间为亚秒级。有空间认为应该将打印排除在时间计算之外；但这让事情变得更加混乱，所以我没有打扰。我已经修复了以前版本中的错误：循环 4 与循环 3 相同 - 现在不是了。我还改进了输出格式（尽管可以改进亚秒级处理 - 读者练习），并且有更好的“进度报告”。]

在 Mac Mini（Snow Leopard 10.6.2）上的计时结果是：

Count up   $s *= $i:      00:00:12.663337
Count up   $s  = $s * $i: 00:00:20.686111
Count down $s *= $i:      00:00:14.201797
Count down $s  = $s * $i: 00:00:23.269874

脚本：

use Time::HiRes qw(gettimeofday);
use strict;
use warnings;
use bigint;
use constant factorial_of => 13000;

sub delta_t
{
    my($tag, $t1, $t2) = @_;
    my($d) = int($t2 - $t1);
    my($f) = ($t2 - $t1) - $d;
    my($s) = sprintf("%.6f", $f);
    $s =~ s/^0//;
    printf "%-25s %02d:%02d:%02d%s\n",
           $tag, int($d/3600), int(($d % 3600) / 60), int($d % 60), $s;
}

my $t1 = gettimeofday;

{
    my $n = factorial_of;
    my $s = 1;
    for (my $i = 2; $i <= $n; $i++)
    {
        $s *= $i;
    }
    print "$s\n: Loop 1\n";
}

my $t2 = gettimeofday;
delta_t('Count up   $s *= $i:',      $t1, $t2);

{
    my $n = factorial_of;
    my $s = 1;
    for (my $i = 2; $i <= $n; $i++)
    {
        $s = $s * $i;
    }
    print "$s\n: Loop 2\n";
}

my $t3 = gettimeofday;
delta_t('Count up   $s *= $i:',      $t1, $t2);
delta_t('Count up   $s  = $s * $i:', $t2, $t3);

{
    my $n = factorial_of;
    my $s = 1;
    for (my $i = $n; $i > 1; $i--)
    {
        $s *= $i;
    }
    print "$s\n: Loop 3\n";
}

my $t4 = gettimeofday;
delta_t('Count up   $s *= $i:',      $t1, $t2);
delta_t('Count up   $s  = $s * $i:', $t2, $t3);
delta_t('Count down $s *= $i:',      $t3, $t4);

{
    my $n = factorial_of;
    my $s = 1;
    for (my $i = $n; $i > 1; $i--)
    {
        $s = $s * $i;
    }
    print "$s\n: Loop 4\n";
}

my $t5 = gettimeofday;
delta_t('Count up   $s *= $i:',      $t1, $t2);
delta_t('Count up   $s  = $s * $i:', $t2, $t3);
delta_t('Count down $s *= $i:',      $t3, $t4);
delta_t('Count down $s  = $s * $i:', $t4, $t5);

---

这是上面代码的一个更紧凑的版本，扩展为测试“while”循环和“for”循环。它还处理大多数时间问题。唯一不理想的（对我来说）是它使用了几个全局变量，我稍微整理了代码参考中的代码，所以它都适合一行而不触发滚动条（无论如何，在我的显示器上）。显然，通过更多的工作，可以将测试包装到一个数组中，以便迭代地完成测试 - 通过数组循环运行对数组中的信息的计时器函数。等等......这是一个 SMOP - 简单的编程问题。 （它打印阶乘的 MD5 哈希，而不是阶乘本身，因为它更容易比较结果等。它确实指出了一些错误，因为我正在重构上面的代码。是的，MD5 不安全 -但我不是为了安全而使用它；只是为了发现无意的变化。）

use Time::HiRes qw(gettimeofday);
use Digest::MD5 qw(md5_hex);
use strict;
use warnings;
use bigint;
use constant factorial_of => 13000;

my ($s, $i);

my $l1 = sub {my($n) = @_; for ($i = 2;  $i <= $n; $i++) { $s *= $i;     }};
my $l2 = sub {my($n) = @_; for ($i = 2;  $i <= $n; $i++) { $s = $s * $i; }};
my $l3 = sub {my($n) = @_; for ($i = $n; $i > 1;   $i--) { $s *= $i;     }};
my $l4 = sub {my($n) = @_; for ($i = $n; $i > 1;   $i--) { $s = $s * $i; }};
my $l5 = sub {my($n) = @_; $i = 2;  while ($i <= $n) { $s *= $i;     $i++; }};
my $l6 = sub {my($n) = @_; $i = 2;  while ($i <= $n) { $s = $s * $i; $i++; }};
my $l7 = sub {my($n) = @_; $i = $n; while ($i > 1)   { $s *= $i;     $i--; }};
my $l8 = sub {my($n) = @_; $i = $n; while ($i > 1)   { $s = $s * $i; $i--; }};

sub timer
{
    my($n, $code, $tag) = @_;
    my $t1 = gettimeofday;
    $s = 1;
    &$code(factorial_of);
    my $t2 = gettimeofday;
    my $md5 = md5_hex($s);
    printf "Loop %d: %-33s %09.6f (%s)\n", $n, $tag, $t2 - $t1, $md5;
}

my $count = 1;
timer($count++, $l1, 'for   - Count up   $s *= $i:');
timer($count++, $l2, 'for   - Count up   $s  = $s * $i:');
timer($count++, $l3, 'for   - Count down $s *= $i:');
timer($count++, $l4, 'for   - Count down $s  = $s * $i:');
timer($count++, $l5, 'while - Count up   $s *= $i:');
timer($count++, $l6, 'while - Count up   $s  = $s * $i:');
timer($count++, $l7, 'while - Count down $s *= $i:');
timer($count++, $l8, 'while - Count down $s  = $s * $i:');

示例输出（MD5 校验和压缩以避免换行 - 完整值为 584b3ab832577fd1390970043efc0ec8）：

Loop 1: for   - Count up   $s *= $i:      12.853630 (584b3ab8...3efc0ec8)
Loop 2: for   - Count up   $s  = $s * $i: 20.854735 (584b3ab8...3efc0ec8)
Loop 3: for   - Count down $s *= $i:      14.798155 (584b3ab8...3efc0ec8)
Loop 4: for   - Count down $s  = $s * $i: 23.699913 (584b3ab8...3efc0ec8)
Loop 5: while - Count up   $s *= $i:      12.972428 (584b3ab8...3efc0ec8)
Loop 6: while - Count up   $s  = $s * $i: 21.192956 (584b3ab8...3efc0ec8)
Loop 7: while - Count down $s *= $i:      14.555620 (584b3ab8...3efc0ec8)
Loop 8: while - Count down $s  = $s * $i: 23.790795 (584b3ab8...3efc0ec8)

我一直看到 'while' 循环相对于相应的 'for' 循环有一个小的 (

Answer 3

基准测试的一个关键是简化。提出的问题是for 与while 的速度。但实验涉及一些不必要的复杂性。

• 这两个循环并不像它们可能的那样相似。一个使用$s *= $n，另一个使用$s = $s * $i（正如Jonathan Leffler 指出的那样）。一个使用$n--，另一个使用$i++（谁知道它们的速度是否不同？）。

• 如果我们对for 与while 感兴趣，则无需涉及bigint。那只会混淆主题。特别是，您的while 脚本仅依赖一个bigint 对象（$s），而您的for 脚本使用其中两个（$s 和$i）。 for 脚本速度较慢并不让我感到惊讶。

重写你的循环尽可能相似，保持因子足够小，这样你就不必使用bigint，并使用Benchmark 模块。然后你就可以在for 与while 之间进行一场公平的正面交锋。我很想看看你发现了什么。