首先，您必须将%1 存储到一个变量中，然后您才能执行替换。
基本上，替换的语法是这样的：
%<i>variable</i>:<i>str1</i>=<i>str2</i>%
这意味着：'将variable 中的每个str1 替换为str2'。
在您的情况下，str1 和 str2 都是参数，而不是文字字符串。直接使用上面的模板，你可能会得到这个表达式：
%variable:%3=%4%.
但这会使解析器感到困惑，因为它不知道应该首先评估%3 和%4。事实上，它会首先尝试评估%variable:%（并失败）。
在这种情况下，一种解决方案可能是使用一种称为'lazy'延迟评估的方法。基本上，您将评估变量的命令传递给 CALL 命令。原始命令到它的“CALL 版本”的转换是这样的：
ECHO %var% ==> CALL ECHO %%var%%.
注意双重%s。在解析时，它们被评估为单个 %s。生成的命令将由 CALL 再次解析，最终效果与原始命令的情况相同，ECHO %var%。
所以它的工作原理与原始命令相同（这很好），我们在这里获得的是评估的后期时间，我的意思是最终评估，当变量实际被替换时以其价值。了解了这种效果，我们可以构造表达式，首先计算 %3 和 %4，然后计算整个结果表达式。具体来说，像这样：
%%variable:%3=%4%%
第一次解析后，这个表达式会变成这样：
%variable:x=y%
这将被再次解析，输出将是 variable 修改后的内容。
为了更好地说明，这里有一个简单的工作示例：
SET "output=%1"
CALL SET output=%%output:%3=%4%%
ECHO %output%
更新
还有另一种方法可以做同样的事情，我可能应该先提到它。
Windows 命令外壳支持正确 延迟扩展。它使用起来更简单，但有一些注意事项。
首先，如何使用它。延迟扩展的语法是!var!，而不是立即扩展的%var%（它仍然有效，可以与延迟扩展语法一起使用）。
在您使用以下命令启用语法之前，!var! 可能无法在您的脚本中运行：
SETLOCAL EnableDelayedExpansion
ENDLOCAL 命令关闭延迟扩展语法在其中有效并由命令 shell 解释的块。
上面的示例脚本可以这样重写：
SET "output=%1"
SETLOCAL EnableDelayedExpansion
SET output=!output:%3=%4!
ECHO !output!
ENDLOCAL
那么在SET output=!output:%3=%4! 命令的情况下这是如何工作的：
-
%3 和 %4 被立即评估，即在解析时——它们分别被 x 和 y 替换；
-
命令变成这样：SET output=!output:x=y!;
-
命令即将执行 - 评估 ! 表达式（xs 替换为 ys）；
-
命令被执行——output 变量被修改。
现在关于注意事项。首先要记住的是! 成为语法的一部分，并在遇到时被使用和解释。所以你需要在你想用它作为文字的地方转义它（比如^!）。
另一个警告是 SETLOCAL/ENDLOCAL 块的主要影响。问题是，在这样一个块中对环境变量的所有更改都是本地的。在退出块时（在执行ENDLOCAL 时），变量被设置为进入它之前的值（在执行SETLOCAL 之前）。这对您来说意味着 output 的更改值将仅在 SETLOCAL 块内有效，您必须首先启动该块以使用延迟扩展。如果您只需要修改该值然后立即使用它，在您的特定情况下这可能不是问题，但您可能必须记住它以备将来使用。
注意：根据 jeb 的评论，您可以使用此技巧保存修改后的值并离开 SETLOCAL 块：
ENDLOCAL & SET "output=%output%"
& 运算符只是将命令放在同一行时对其进行分隔。它们按照指定的顺序一个接一个地执行。问题是，在解析行的那一刻，SETLOCAL 块还没有离开，所以%output% 评估为修改后的值，它仍然有效。但是赋值实际上是在之后 ENDLOCAL 执行的，即在离开块之后。因此，您在离开块后有效地存储了修改后的值，从而保留了更改。 （谢谢，jeb！）
更多信息：
- 关于延迟扩展：
- 关于子串替换：