如何在 Perl 中进行条件（“如果存在”逻辑）搜索和替换？

Question

在我的 Perl 脚本中，我想使用正则表达式进行条件搜索和替换：查找某个模式，如果该模式存在于哈希中，则将其替换为其他内容。

例如，我要搜索“pattern1”和“pattern2”的组合，如果后者存在于哈希中，则将组合替换为“pattern1”和“replacement”。我尝试了以下方法，但它根本没有做任何事情。

$_ =~ s/(pattern1)(pattern2)/$1replacement/gs if exists $my_hash{$2};

我也尝试过类似的东西：

$_ =~ s/(pattern1)(pattern2) && exists $my_hash{$2}/$1replacement/gs;

也什么都不做，好像没有找到匹配一样。

谁能帮我解决这个正则表达式问题？谢谢~

Answer 1

我会以不同的方式来做。看起来你有一个“搜索这个，替换那个”哈希。

所以：

#!/usr/bin/env perl
use strict;
use warnings;

#our 'mappings'. 
#note - there can be gotchas here with substrings
#so make sure you anchor patterns or sort, so 
#you get the right 'substring' match occuring. 

my %replace = (
    "this phrase" => "that thing",
    "cabbage"     => "carrot"
);

#stick the keys together into an alternation regex. 
#quotemeta means regex special characters will be escaped. 
#you can remove that, if you want to use regex in your replace keys.     
my $search = join( "|", map {quotemeta} keys %replace );
#compile it - note \b is a zero width 'word break' 
#so it will only match whole words, not substrings. 
$search = qr/\b($search)\b/;

#iterate the special DATA filehandle - for illustration and a runnable example. 
#you probably want <> instead for 'real world' use. 
while (<DATA>) {
    #apply regex match and replace
    s/(XX) ($search)/$1 $replace{$2}/g;
    #print current line. 
    print;
}

##inlined data filehandle for testing. 
__DATA__
XX this phrase cabbage
XX cabbage carrot cabbage this phrase XX this phrase
XX no words here
and this shouldn't cabbage match this phrase at all

通过这样做，我们将您的哈希键转换为正则表达式（您可以打印它 - 它看起来像：(?^:\b(cabbage|this\ phrase)\b)

插入到替换模式中。这将仅在密钥存在时匹配，因此您可以安全地进行替换操作。

注意 - 我添加了quotemeta，因为它会转义键中的任何特殊字符。 \b 是一个“单词边界”匹配，因此它不会在单词中使用子字符串。 （很明显，如果你确实想要那个，那就摆脱它们）

上面给出的输出：

XX that thing cabbage
XX carrot carrot cabbage this phrase XX that thing
XX no words here
and this shouldn't cabbage match this phrase at all

如果你想省略 不 模式匹配的行，你可以在正则表达式后面加上&& print;。

Answer 2

有什么问题（如不工作）

if (exists($h{$patt1)) { $text =~ s/$patt1$patt2/$patt1$1replacement/g; }

如果$patt1 存在作为哈希中的键，那么您继续将$patt1$patt2 替换为$patt1$replacement。当然，如果在$text 中找到了$patt1$patt2，否则什么也不会发生。您的第一个代码 sn-p 是循环的，而第二个代码根本不能那样工作。

如果你首先想要$patt1$patt2，和哈希键，那么你似乎必须慢慢来

if ($str =~ /$patt11$patt2/ && exists $h{$patt2}) {
     $str =~ s/$patt1$patt2/$patt1$replacement/gs;
}

如果这是你想要的，那么它真的很简单：你需要两个不相关的条件，无论你以哪种方式扭转它。不能将它们组合起来，因为它是圆形的。

从结果的角度来看，这些是相同的。如果任一条件失败，则无论您检查它们的顺序如何，都不会发生任何事情。

注意 或者你也不必慢慢来，见Sobrique的帖子。