将表单输入值从 HTA 返回到打开它的 VBS 脚本答案

【问题标题】：Return form input values from an HTA to a VBS script that opened it将表单输入值从 HTA 返回到打开它的 VBS 脚本
【发布时间】：2015-07-09 23:25:06
【问题描述】：

我有一个映射驱动器的 VBS 脚本。根据用户，映射通用文件夹（不需要凭据）或个人文件夹（需要用户名和密码）。我目前正在为此使用标准 WSH 输入，这显然不太安全，因为密码没有被屏蔽

我已经使用 ScriptPW.dll 研究过解决方案，但这不再是 Windows 的本机（我使用的是 Windows 7），并且在从 XP 复制并注册时不起作用。

我现在正在研究的一个解决方案是使用 HTA 来提示输入用户名/密码。我已经到了在需要时运行文件的地步，但我不确定如何（或者即使我可以）将输入值从表单返回到父脚本。

这可能吗？

注意 - 由于并非在所有情况下都需要该表格，因此我无法将整个脚本放在 HTA 中。

这就是我如何称呼 HTA -

Dim Shell
Set Shell = Wscript.CreateObject("Wscript.Shell")
Shell.Run("test.hta"), 1, True
Set Shell = Nothing

这是 HTA -

<html>
<head>
    <meta http-equiv="Content-Type" content="text/html; charset=windows-1252" />
    <title>Login Application</title>
    <hta :application
        applicationname="LoginBox"  
        border="dialog"
        borderstyle="normal"
        caption="My HTML Application"
        contextmenu="no"
        maximizebutton="no"
        minimizebutton="yes"
        navigable="no"
        selection="no"
        showintaskbar="yes"
        singleinstance="yes"
        sysmenu="yes"
        version="1.0"
        windowstate="normal" />

</head>
<body>
    <form id="LoginForm">
        Enter Username: <input type="textbox" id="UserName"/><br />
        Enter Password: <input type="password" id="Password"/><br />
        <input type="submit" value="Open my scans"/>
    </form>
</body>
</html>

【问题讨论】：

不要将用户名和密码返回给调用者。在 HTA 中映射驱动器

标签： vbscript hta

【解决方案1】：

我觉得PasswordBox这个功能可以帮到你，试试看吧;)

' Just an example of how to use the function
 '
 wsh.echo "You entered: ", _
          Join(PasswordBox("Enter UID and password", _
               "Testing"), ", ")

 ' A function to present a Password dialog in a VBS (WSF) 
 ' script
 ' Requires WScript version 5.1+
 ' Tom Lavedas <tlavedas@hotmail.com>
 ' with help from and thanks to Joe Ernest and 
 ' Michael Harris
 '
 ' modified 1/2008 to handle IE7
 '
 Function PasswordBox(sPrompt,sDefault)
   set oIE = CreateObject("InternetExplorer.Application")
   With oIE
 ' Configure the IE window
     .RegisterAsDropTarget = False
     .statusbar = false : .toolbar    = false
     .menubar   = false : .addressbar = false
     .Resizable = False 
     .Navigate "about:blank"
     Do Until .ReadyState = 4 : WScript.Sleep 50 : Loop
 ' Test for IE 7 - cannot remove 'chrome' in that version
     sVersion  = .document.parentWindow.navigator.appVersion  
     if instr(sVersion, "MSIE 7.0") = 0 Then .FullScreen = True 
     .width = 400       : .height = 270
 ' Create the password box document
     With .document
       oIE.left = .parentWindow.screen.width \ 2 - 200
       oIE.top  = .parentWindow.screen.height\ 2 - 100
       .open
       .write "<html><head><" & "script>bboxwait=true;</" _
            & "script><title>Password _</title></head>"_
            & "<body bgColor=silver scroll=no " _
            & "language=vbs style='border-" _ 
            & "style:outset;border-Width:3px'" _
            & " onHelp='window.event.returnvalue=false" _
            & ":window.event.cancelbubble=true'" _
            & " oncontextmenu=" _ 
            & "'window.event.returnvalue=false" _
            & ":window.event.cancelbubble=true'" _
            & " onkeydown='if ((window.event.keycode>111)"_
            & " and  (window.event.keycode<117)) or" _
            & " window.event.ctrlkey then" _
            & " window.event.keycode=0" _
            & ":window.event.cancelbubble=true" _
            & ":window.event.returnvalue=false'" _
            & " onkeypress='if window.event.keycode=13" _
            & " then bboxwait=false'><center>" _
            & "<div style='padding:10px;background-color:lightblue'>" _
            & "<b>&nbsp" & sPrompt & "<b>&nbsp</div><p>" _
            & "<table bgcolor=cornsilk cellspacing=10><tr><td>" _
            & " <b>User:</b></td><td>" _
            & "<input type=text size=10 id=user value='" _
            & sDefault & "'>" _
            & "</td><tr><td> <b>Password:</b></td><td>" _
            & "<input type=password size=12 id=pass>" _ 
            & "</td></tr></table><br>" _
            & "<button onclick='bboxwait=false;'>" _
            & "&nbsp;Okay&nbsp;" _
            & "</button> &nbsp; <button onclick=" _
            & "'document.all.user.value=""CANCELLED"";" _
            & "document.all.pass.value="""";" _
            & "bboxwait=false;'>Cancel" _
            & "</button></center></body></html>"
       .close
       Do Until .ReadyState = "complete" : WScript.Sleep 100 : Loop
       .all.user.focus
       .all.user.select ' Optional
       oIE.Visible = True
       CreateObject("Wscript.Shell")_
         .Appactivate "Password _"
       PasswordBox = Array("CANCELLED")
       On Error Resume Next
       Do While .parentWindow.bBoxWait
         if Err Then Exit Function
         WScript.Sleep 100
       Loop
       oIE.Visible = False
       PasswordBox = Array(.all.user.value, _
                           .all.pass.value)
     End With ' document
   End With   ' IE
 End Function

【讨论】：

这就像一个魅力，除了在标题中添加一些 CSS（这只是我是强迫症），它开箱即用。感谢发帖。