将字符从小写转换为大写，反之亦然 VB.Net

Question

四处搜索，找不到答案。

我的任务是将字符串大小写从小写或大写转换为大写，然后将它们四舍五入..

例如：- 输入：- “HeLlO”和输出：- “hElLo”

我知道我需要使用 for 循环，但无法弄清楚如何逐步遍历每个字符、检查大小写并在需要时切换它。

我可以创建一个 for 循环来计数并显示单个字符或一个简单的 If 语句将整个字符串转换为大写或小写，但如果我尝试将 2 组合起来，我的逻辑就无法正常工作。

任何人都可以帮忙吗？

Answer 1

作为 Linq 查询：

Dim input = "HeLlO"
Dim output = new String(input.Select(Function(c)
                            Return If(Char.IsLower(c),Char.ToUpper(c),Char.ToLower(c))
                        End Function).ToArray())
Console.WriteLine(output)

老实说，这些天谁写循环？ :-)

Answer 2

这是一种简单的方法：

Public Function InvertCase(input As String) As String
    Dim output As New StringBuilder()
    For Each i As Char In input
        If Char.IsLower(i) Then
            output.Append(Char.ToUpper(i))
        ElseIf Char.IsUpper(i) Then
            output.Append(Char.ToLower(i))
        Else
            output.Append(i)
        End If
    Next
    Return output.ToString()
End Function

它只是遍历原始字符串中的每个字符，检查它的大小写，修复它，然后将固定的字符附加到新字符串（通过StringBuilder 对象）。

正如 Neolisk 在下面的 cmets 中建议的那样，您可以通过创建另一种转换单个字符的方法来使其更简洁，如下所示：

Public Function InvertCase(input As Char) As Char
    If Char.IsLower(input) Then Return Char.ToUpper(input)
    If Char.IsUpper(input) Then Return Char.ToLower(input)
    Return input
End Function

Public Function InvertCase(input As String) As String
    Dim output As New StringBuilder()
    For Each i As Char In input
        output.Append(InvertCase(i))
    Next
    Return output.ToString()
End Function

对InvertCase(Char) 使用相同的函数，您也可以使用 LINQ，如下所示：

Public Function InvertCase(input As String) As String
    Return New String(input.Select(Function(i) InvertCase(i)).ToArray())
End Function