MaybeT m 的应用实例假设 Monad m

Question

我一直在使用Haxl monad（在此描述：http://www.reddit.com/r/haskell/comments/1le4y5/the_haxl_project_at_facebook_slides_from_my_talk），它的 Applicative 实例的 <*> 与 Control.Monad 中的 ap 不同。这是一个关键特性，允许它在不阻塞的情况下进行并发计算。例如，如果hf 和ha 是长计算，那么

let hf :: Haxl (a -> b) = ...
    ha :: Haxl a = ...
in do
  f <- hf
  a <- ha
  return (f a)

将按顺序执行，而

hf <*> ha

将并行执行，然后合并结果。

我希望能够在 MaybeT Haxl 中运行计算，但问题是转换器包中 MaybeT m 的 Applicative 实例使用一元绑定：

instance (Functor m, Monad m) => Applicative (MaybeT m) where
    pure = return
    (<*>) = ap

ap = liftM2 id 来自Control.Monad。这使得

let hmf :: MaybeT Haxl (a -> b) = ...
    hma :: MaybeT Haxl a = ...
in hmf <*> hma

按顺序运行。似乎更好的实例会更像

instance (Applicative m) => Applicative (MaybeT m) where
    pure = MaybeT . pure . Just
    MaybeT f <*> MaybeT x = MaybeT $ (<*>) <$> f <*> x

（这里，右侧的(<*>) 用于Maybe monad，而右侧不带括号的<*> 用于m。）注意上下文不同-- 上面的实例只假设Applicative m，而transformers中的实例假设Functor m, Monad m。

我的主要问题是实际的：我应该怎么做？我应该推出自己的MaybeT monad 变压器吗？如果我尝试编写上述内容，是否有某种方法可以解决 ghc 给我的“重复实例声明”投诉？

我也想知道：目前的设置是变压器包中的设计缺陷吗？如果没有，为什么不呢？

Answer 1

诀窍在于（与 monad 不同）应用函子是可组合的，因此您不需要像 MaybeT 这样的（应用）转换器。相反，您可以使用Compose 将两个应用函子组合在一起：

import Control.Applicative
import Data.Functor.Compose

type HaxlM = Compose Haxl Maybe

-- if you prefer to have a function for constructing values:
haxlM :: Haxl (Maybe a) -> HaxlM a
haxlM = Compose

组合始终是Applicative 的正确实例，并且仅使用其组件的Applicative 实例。例如：

test = getZipList . getCompose
       $ (+) <$> Compose (ZipList [Just 1,  Nothing, Just 3])
             <*> Compose (ZipList [Nothing, Just 20, Just 30])

产生[Nothing,Nothing,Just 33]。