如何在 Haskell 中使用 IO 制作随机列表

Question

我正在尝试进行集群模拟，以便更好地自学haskell。在尝试为需要随机性的模拟生成初始状态时，我遇到了麻烦。我正在尝试生成所有具有随机初始位置和方向的 Boid 列表。

在主函数中我使用

let numBoids = 10
rBoids <- randomBoids numBoids

rBoids 我打算将其存储在 IORef 中，然后我可以更新每一帧，我认为这是正确的做法吗？

这是失败的代码：

-- Type for the flocking algorithm
data Boid = Boid {
    boidPosition  :: Vector2(GLfloat)
  , boidDirection :: Vector2(GLfloat)
  } deriving Show

randomBoids :: Int -> IO ([Boid])
randomBoids 0 = do
  return []
randomBoids n = do
  b <- randomBoid 
  bs <- (randomBoids (n-1))
  return b : bs

randomBoid = do
  pos <- randomVector
  vel <- randomVector
  return (Boid pos vel)

randomVector = do
  x <- randomRIO(-1.0, 1.0)
  y <- randomRIO(-1.0, 1.0)
  return (Vector2 x y)

实际上失败的是return b : bs。如果我将其更改为 return [b] 它会编译。给出的错误是：

Couldn't match expected type `IO [Boid]' with actual type `[a0]'
In the expression: return b : bs
In the expression:
  do { b <- randomBoid;
       bs <- (randomBoids (n - 1));
         return b : bs }
In an equation for `randomBoids':
    randomBoids n
      = do { b <- randomBoid;
             bs <- (randomBoids (n - 1));
               return b : bs }

我在这里很迷茫，至少可以说我对整个函数式命令式代码（和 monad）的理解是不稳定的。任何帮助将不胜感激！

Answer 1

类型检查器将return x : xs 读取为(return x) : xs。如果你写return (x:xs)，它会进行类型检查。

Answer 2

Gangadahr 是正确的。我只想提一下，您可以大大缩短代码：

import Control.Applicative
import Control.Monad

randomBoids n = replicateM n randomBoid

randomBoid = Boid <$> randomVector <*> randomVector

randomVector = Vector2 <$> randomRIO (-1, 1) <*> randomRIO (-1, 1)

第一个函数利用了replicateM，当你想重复一个单子动作并收集结果时，这是一个非常有用的函数。后两个函数使用Applicative风格，非常有用。

Answer 3

您收到错误的原因是因为return b : bs 会使编译器将其解释为(return b): bs 要解决此问题，您可以将语句更改为return (b:bs)。这将使语句返回IO[Boid]