在 VBA 中复制和粘贴时代码停止 [重复]

Question

我在用 ** 表示的行上遇到应用程序定义或对象定义错误。我的语法错了吗？

Sub MonthLines()

Dim wkb As Workbook, shifts As Worksheet, inputs As Worksheet, StartDate As Range, EndDate As Range, InputDate As Range, numshifts As Integer, monthstart As Double
Dim monthend As Double, i As Double, n As Double, p As Double

Set wkb = Excel.Workbooks("Call Center Headcount Model v2.xlsm")
Set shifts = wkb.Worksheets("Shifting")
Set inputs = wkb.Worksheets("Inputs")

Set StartDate = wkb.Worksheets("Inputs").Range("C9")
Set EndDate = wkb.Worksheets("Inputs").Range("C10")
Set InputDate = wkb.Worksheets("Shifting").Range("B5")

monthstart = StartDate.Value
monthend = EndDate.Value

Application.Calculation = xlCalculationManual
p = 1

    For i = monthstart To monthend
        InputDate.Value = i
        Calculate
        numshifts = wkb.Worksheets("Shifting").Range("E5").Value
        For n = 21 To numshifts + 21
            With Sheets("Shifting")
            .Range(Cells(n, 1), Cells(n, 6)).Copy
            **wkb.Worksheets("Shift Output").Range(Cells(p, 1), Cells(p, 6)).PasteSpecial Paste:=xlPasteValues**
            End With
        Next n
    p = p + n
    
    Next i
    End Sub

Answer 1

这是一个很好的例子，说明为什么完全限定所有范围对象总是有价值的，即使当时您认为它不是必要的。

确定您的first line below the With statement works，可能是因为您激活了该工作表。因此，VBA 隐式分配您在运行时到达该行时碰巧拥有的任何活动工作表。这就是为什么您的所有范围对象都应该是完全限定的，其中包括Range() 中的Cells()。您在工作表中很好地限定了Range()，但该限定不扩展到Cells() 函数中：
.Range(Cells(n, 1), Cells(n, 6)) 或
wkb.Worksheets("Shift Output").Range(Cells(p, 1), Cells(p, 6))

未经测试，但这应该可以工作：

Dim wsShift As Worksheet, wsSO As Worksheet
Set wsShift = wkb.Worksheets("Shifting")
Set wsSO = wkb.Worksheets("Shift Output")

For i = monthstart To monthend

    InputDate.Value = i
    Calculate
    numshifts = wkb.Worksheets("Shifting").Range("E5").Value
    
    For n = 21 To numshifts + 21
        wsShift.Range(wsShift.Cells(n, 1), wsShift.Cells(n, 6)).Copy
        wsSO.Range(wsSO.Cells(p, 1), wsSO.Cells(p, 6)).PasteSpecial Paste:=xlPasteValues
    Next n
    
    p = p + n

Next i

或者如果你真的想精通，放弃众所周知的慢循环 + .Copy/.Paste 方法并使用数组。读一次，一次正确，而不是读/写numShifts - 21 次：（再次，未经测试）

Dim dataArr() As Variant
dataArr = Workbooks("<ENTER WB>").Worksheets("Shifting").Range("A21:F" & numshifts + 21).Value
wkb.Worksheets("Shift Output").Range("A1:F" & numshifts + 21).Value = dataArr