有没有办法循环直到多维数组在 VBA 中已满？

Question

有没有一种简单的方法来实现一个循环，直到多维数组中的每个值都不是每个类型的“空” - 所以循环直到字符串数组被非空字符串的值填充，等等。

我要做的伪代码示例：

 Dim MultiArray(100,100) As String

 Do Until MultiArray(0,0) To MultiArray (100,100) Is Not = ""
      'Operations
 Loop

Answer 1

这“简单”吗？

For i = 0 To 100

    For j = 0 To 100

        'Operations
        MultiArray(i, j) = 1

    Next j

Next i

编辑

Function IsArrayFilled(ByRef Multi_Array() As String) As Boolean

    Dim i As Long, j As Long

    For i = LBound(Multi_Array, 1) To UBound(Multi_Array, 1)

        For j = LBound(Multi_Array, 2) To UBound(Multi_Array, 2)

            If Multi_Array(i, j) = "" Then ' If there are ANY blank strings, then terminate the function immediately and return false

                IsArrayFilled = False
                Exit Function

            End If

        Next j

    Next i

    ' If we got through the whole array without finding any blank strings, then return true
    IsArrayFilled = True

End Function

Sub Test()

    Dim MultiArray(0 To 100, 0 To 100) As String

    Do While Not IsArrayFilled(MultiArray)

        'Operations

    Loop

End Sub

请注意，这是一个非常昂贵的函数，因为它会在每次检查时尝试遍历整个数组，即随着数组被填满，它会逐渐变慢。我不确定为什么需要检查空字符串以及为什么不能简单地遍历数组一次。但是，这是我知道的唯一方法，可以满足您的要求。

Answer 2

您有一个 2D 数组，因此唯一可能迭代所有值的循环构造是 nested For loop。

如果我正确理解了您的问题陈述，您希望在遇到空字符串值时跳出嵌套循环。

这对 该数组中的实际内容做了很多假设。让我们首先假设一个行/列布局，分别在维度索引 1 和 2 中 - 因为我们不知道数据来自哪里（工作表范围？某个文件？硬编码？），我们不要硬编码循环的上下界：

Dim row As Long
For row = LBound(data, 1) To UBound(data, 1)

    Dim break As Boolean
    Dim col As Long
    For col = LBound(data, 2) To UBound(data, 2)

        'Operations

        Dim value As Variant
        value = CStr(data(row, col))

        If value = vbNullString Then
            break = True
            Exit For
        End If

    Next
    If break Then Exit For
Next

但有一个问题：只要遇到一个空字符串，它就会跳出循环——这可能是也可能不是你想要的。

如果您想在发现每一列都包含一个空字符串的行时停止迭代行，那么不是这样。你需要更精确的逻辑。像这样的：

Dim row As Long
For row = LBound(data, 1) To UBound(data, 1)

    Dim rowContents As String
    Dim col As Long
    For col = LBound(data, 2) To UBound(data, 2)

        'Operations

        rowContents = rowContents & CStr(data(row, col))

    Next
    If Strings.Trim(rowContents) = vbNullString Then Exit For
Next

请注意，如果任何“单元格”包含错误值，这两个循环都会崩溃。您可以使用IsError 函数来防止这种情况发生。

但话又说回来，这是假设您正在迭代行。如果您在 Excel 中并且正在迭代一个二维数组，其中第一个维度表示行，并且您希望在找到一个只包含空“单元格”的“行”时停止循环，那么你试图解决的真正问题是“在一个范围内找到最后使用的行”，而你所做的一切都是徒劳的，this answer 是你真正 em> 想用：

With Sheets("Sheet1")
    If Application.WorksheetFunction.CountA(.Cells) <> 0 Then
        lastrow = .Cells.Find(What:="*", _
                      After:=.Range("A1"), _
                      Lookat:=xlPart, _
                      LookIn:=xlFormulas, _
                      SearchOrder:=xlByRows, _
                      SearchDirection:=xlPrevious, _
                      MatchCase:=False).Row
    Else
        lastrow = 1
    End If
End With

我可以继续推断你整天真正想要实现的目标，但我会停在这里。