Prolog - 计算列表中的重复次数

Question

我正在尝试查看列表并计算给定单词出现的次数。到目前为止我已经得到了这个：

count_repetitions([_], [], 0).
count_repetitions([Word], [Word|Tail], Count):-
   count_repetitions([Word], Tail, X), 
   Count is X + 1.
count_repetitions([Word], [Z|Tail], Count):-
   Word \= Z, 
   count_repetitions([Word], Tail, Count).

所以查询?- count_repetitions([yes],[yes,and,yes,and,no], X). 将给出X = 2。

这似乎有效。现在我需要编写一个谓词，输出一个包含搜索词及其出现次数的列表，格式为X = [(yes - 2)]。我完全被卡住了，有什么建议吗？

Answer 1

这个答案显示了一种逻辑上纯粹的方法。以下内容基于clpfd。

:- use_module(library(clpfd)).

我们定义meta-predicate tcount/3 类似于tfilter/3！

:- meta_predicate tcount(2,?,?).
tcount(P_2,Xs,N) :-
   N #>= 0,
   list_pred_tcount_(Xs,P_2,0,N).

:- meta_predicate list_pred_tcount_(?,2,?,?).
list_pred_tcount_([]    , _ ,N ,N).
list_pred_tcount_([X|Xs],P_2,N0,N) :-
   if_(call(P_2,X), (N1 is N0+1, N1 #=< N), N1 = N0),
   list_pred_tcount_(Xs,P_2,N1,N).

现在让我们将tcount/3 与(=)/3 结合使用：

?- tcount(=(yes),[yes,and,yes,and,no],Count).
Count = 2.

与所有此问题的其他答案提供的代码不同，此答案中提供的代码是单调，即使与非基本术语一起使用也能保持逻辑合理：

?- tcount(=(yes),[A,B,C,D],2).
      A=yes ,     B=yes , dif(C,yes), dif(D,yes)
;     A=yes , dif(B,yes),     C=yes , dif(D,yes)
;     A=yes , dif(B,yes), dif(C,yes),     D=yes
; dif(A,yes),     B=yes ,     C=yes , dif(D,yes)
; dif(A,yes),     B=yes , dif(C,yes),     D=yes
; dif(A,yes), dif(B,yes),     C=yes ,     D=yes
; false.

让我们尝试一些更通用的方法：

?- tcount(=(yes),[A,B,C,D],Count).
      A=yes ,     B=yes ,     C=yes ,     D=yes , Count = 4
;     A=yes ,     B=yes ,     C=yes , dif(D,yes), Count = 3
;     A=yes ,     B=yes , dif(C,yes),     D=yes , Count = 3
;     A=yes ,     B=yes , dif(C,yes), dif(D,yes), Count = 2
;     A=yes , dif(B,yes),     C=yes ,     D=yes , Count = 3
;     A=yes , dif(B,yes),     C=yes , dif(D,yes), Count = 2
;     A=yes , dif(B,yes), dif(C,yes),     D=yes , Count = 2
;     A=yes , dif(B,yes), dif(C,yes), dif(D,yes), Count = 1
; dif(A,yes),     B=yes ,     C=yes ,     D=yes , Count = 3
; dif(A,yes),     B=yes ,     C=yes , dif(D,yes), Count = 2
; dif(A,yes),     B=yes , dif(C,yes),     D=yes , Count = 2
; dif(A,yes),     B=yes , dif(C,yes), dif(D,yes), Count = 1
; dif(A,yes), dif(B,yes),     C=yes ,     D=yes , Count = 2
; dif(A,yes), dif(B,yes),     C=yes , dif(D,yes), Count = 1
; dif(A,yes), dif(B,yes), dif(C,yes),     D=yes , Count = 1
; dif(A,yes), dif(B,yes), dif(C,yes), dif(D,yes), Count = 0.

下面的极端情况呢？

?- tcount(_,_,-1).
false.

那么使用tcount/3 作为length/2 的替代品怎么样？

?- 1..3 中的 N，长度（Xs，N）。 N = 1，Xs = [_A] ; N = 2, Xs = [_A,_B] ; N = 3, Xs = [_A,_B,_C] ... % 不终止 ?- 使用模块（库（lambda））。 真的。 ?- 1..3 中的 N，tcount(\_^ =(true),Xs,N)。 N = 1，Xs = [_A] ; N = 2, Xs = [_A,_B] ; N = 3, Xs = [_A,_B,_C] ;错误。 % 普遍终止

Answer 2

在我看来，你已经在那里了。你可以简单地将你的谓词换成另一种说法：

word_repetitions(Word, List, [(Word-Count)]) :-
    count_repetitions(Word, List, Count).

请注意，Word-Count 对不需要括号或方括号：

word_repetitions(Word, List, Word-Count) :-
    count_repetitions(Word, List, Count).

（但如果你坚持，你可以使用它们）。

在原始谓词上，重命名以反映差异：

list_word_reps([], Word, Word-0).
list_word_reps([W|Rest], Word, Word-Reps) :-
    list_word_reps(Rest, Word, Word-Reps0),
    (   W == Word
    ->  Reps is Reps0 + 1
    ;   Reps = Reps0
    ).

?- list_word_reps([yes,no,yes,no,maybe,yes], yes, X).
X = yes-3.

列表出现在单词之前的原因是谓词因此变得确定性。使用 if-then-else 而不是两个不同的子句也是如此。如果您愿意，您可以将答案放在一个列表中（只需将参数括在括号中），但同样没有必要。

Answer 3

图书馆（聚合）经常被低估：

count(L, C) :-
    aggregate(set(W-N), aggregate(count, member(W, L), N), C).

产量

1 ?- count([a,b,a],C).
C = [a-2, b-1].

所以，越简单

count(W, L, W-N) :-
    aggregate(count, member(W, L), N).

产量

?- count(a, [a,b,a], C).
C = a-2.

基于 setof，aggregate/3 允许更好地控制变量的量化（即聚合哪些值），但如果没有解决方案，则会失败，而不是在某些时候需要产生 0。

aggregate_all/3，基于 findall/3，在这种情况下会返回 0，但不允许使用量化说明符。