VBA 文件夹重命名

Question

我希望使用 VBA 重命名一组文件夹。目的是从文件夹名称中删除特殊字符，例如 - : ; /等。这是我目前所拥有的：

Sub File_renaming2()
Dim objFSO As FileSystemObject, myObj As Object, mySource As Object, Folder As Variant
Set mySource = myObj.GetFolder("C:\Users\John.Doe\Desktop\ABC\VBA Test folder")

For Each Folder In mySource.Folder
    Folder.Name.Replace What:="-", Replacement:=" " 'replace - with space
    Folder.Name.Replace What:=":", Replacement:=" " 'replace : with space
    Folder.Name.Replace What:=";", Replacement:=" " 'replace ; with space
    Folder.Name.Replace What:="/", Replacement:=" " 'replace / with space

    Next Folder

End Sub

我是 VBA 的新手，并且将代码从在线类似问题的解决方案中提取出来，但这似乎给了我

运行时错误“91”- 对象变量或未设置块变量。

感谢任何帮助，谢谢！

Answer 1

已编辑：用户反馈后

您必须在使用它们之前设置所有对象变量

并且你必须与你为他们选择的名字保持一致......（myObj应该是objFSO）

如下代码

Option Explicit

Sub File_renaming2()
    Dim objFSO As FileSystemObject, myObj As Object, mySource As Object, Folder As Variant
    Dim newName As String

    Set objFSO = New FileSystemObject
    Set mySource = objFSO.GetFolder("C:\Users\John.Doe\Desktop\ABC\VBA Test folder")

    For Each Folder In mySource.SubFolders
        newName = Folder.name
        newName = Replace(newName, "-", " ")  'replace - with space
        newName = Replace(newName, ":", " ")  'replace : with space
        newName = Replace(newName, ";", " ")  'replace ; with space
        newName = Replace(newName, "/", " ")  'replace / with space
        If Folder.name <> newName Then Folder.name = newName ' assign new name. the check is to (possibly) ensure you're not processing the same folder twice
    Next Folder
End Sub

因为 FSO 似乎不允许在同一“会话”中更改同一文件夹的名称两次。