如何在 Windows 上仅在批处理文件中设置 PATH 环境变量一次？

Question

我有设置用户路径并作为 Visual Studio IDE 构建步骤的一部分运行的批处理文件。

@ECHO OFF
@ECHO %PATH%
set COMSPEC = "%VCINSTALLDIR%\vcvarsall.bat" amd64
setx PATH "..\..\lib\libsndfile;..\..\lib\simulink" 
@ECHO %PATH%

当我构建项目时，关闭 VS，然后重新打开它，然后重新构建，我看到 附加路径作为PATH 变量的一部分。但是，我看到在 Windows 环境变量的设置中 PATH 变量是在用户环境变量下创建的

..\..\lib\libsndfile;..\..\lib\simulink

问题 1：

为什么此路径也显示为附加路径，作为系统环境变量的一部分？

在通过 Visual Studio 控制台执行echo %PATH% 时（当我第二次运行项目时）打印系统变量路径和我创建的新路径附加到它。

问题 2：

我想修改我的批处理文件，使其在首次运行 Visual Studio 构建期间仅在用户设置中设置一次 PATH 环境变量。如果后续运行时已经存在用户变量PATH，则不应再次执行set命令，以免在系统变量中一次又一次地追加新路径。

任何想法如何实现这一目标？

Answer 1

编辑：经过一些测试，看来我的原始答案并不完全适用于 OP 的问题。更直接地回答OP：

1. %PATH% 将HKLM\System\CurrentControlSet\Control\Session Manager\Environment\Path 中的值与HKCU\Environment\Path 组合在一起。当您setx "dir;dir" 时，您设置的是HKEY_CURRENT_USER Path 值。机器范围内的 HKEY_LOCAL_MACHINE Path 值保持不变。这就是为什么您将您的值视为附加而不是替换的原因。您必须使用 setx /m 替换 HKLM Path 值。 但请不要这样做，除非您想对操作系统安装造成严重问题。

1234563确保所有相对路径、环境变量等都被展平。 set "var=%CD%" 每个。然后if /I "!dir1!"=="!dir2!" 目录已经存在于%PATH% 的某个地方。我在下面的原始答案中有一个例子。

我最初的答案并不完全适用的原因是setx 本身并不像我曾经想象的那样具有破坏性。危险在于，通常当用户想要将目录附加到他们的路径时，他们会setx /m PATH "%PATH%;new dir"；这是破坏性的。因为%PATH%在setx写入值之前展开，所以PATH中的所有目录都过早展开。

以下方法会更安全：

set "env=HKLM\System\CurrentControlSet\Control\Session Manager\Environment"

for /f "tokens=2*" %%I in (
    'reg query "%env%" /v Path ^| findstr /i "\<Path\>"'
) do setx /m PATH "%%J;new directory"

但这并不是 OP 真正要求的，我为下意识的回答道歉。

---

原始答案： setx 具有破坏性，不应以这种方式使用。当您setx PATH 时，您将注册表值数据类型从 REG_EXPAND_SZ 转换为 REG_SZ。执行此操作后，存储在 %PATH% 中的所有动态环境变量都会转换为平坦的绝对路径。使用path 命令临时将目录附加到您的%PATH%，并使用reg add 永久附加目录。 （附带说明一下，还有dpath，它会临时将目录添加到您的路径中，但只能由type 命令使用。向下滚动2/3 this page 以获取有关dpath 的更多信息.)

这是我编写的实用程序脚本，用于以破坏性较小的方式将目录添加到我的%PATH%。它还将避免多次将同一目录添加到 %PATH%，无论其格式如何（例如尾随反斜杠、相对路径、环境变量或任何其他排列）。

@echo off
setlocal enabledelayedexpansion

if not exist "%~1" goto usage

for %%I in ("%~1") do pushd "%%~I" 2>NUL && (set "new=!CD!" && popd) || goto usage
for %%I in ("%PATH:;=";"%") do pushd "%%~I" 2>NUL && (
    rem // delaying expansion of !new! prevents parentheses from breaking things
    if /i "!new!"=="!CD!" (
        echo !new! already exists in %%PATH%%
        goto :EOF
    )
    popd
)

call :append_path "%new%"

goto :EOF

:usage
echo Usage: %~nx0 "dir"
goto :EOF

:append_path <val>
set "env=HKLM\System\CurrentControlSet\Control\Session Manager\Environment"
for /f "tokens=2*" %%I in ('reg query "%env%" /v Path ^| findstr /i "\<Path\>"') do (

    rem // make addition persistent through reboots
    reg add "%env%" /f /v Path /t REG_EXPAND_SZ /d "%%J;%~1"

    rem // apply change to the current process
    for %%a in ("%%J;%~1") do path %%~a
)

rem // use setx to set a temporary throwaway value to trigger a WM_SETTINGCHANGE
rem // applies change to new console windows without requiring a reboot
(setx /m foo bar & reg delete "%env%" /f /v foo) >NUL 2>NUL

color 4E
echo Warning: %%PATH%% has changed.  Reopen the console to inherit the changes.

goto :EOF

Answer 2

1. 这就是 Setx 所做的。请参阅Setx /? 它告诉您这一点。它将它永久添加到用户的环境中（除非使用 /m）。但是 %PATH% 是从系统和用户环境的 PATH 构建的（以及 32 位窗口上的 autoexec.bat，如果通过 ShellExecute 启动，还有 App Paths reg 键））

2. 别担心。如果 %PATH% 中已存在路径，Setx 不会添加到 %PATH% 的路径。

为什么要重新定义系统变量 %COMSPEC%。