从批处理中保持多个控制台窗口打开

Question

如何让批处理文件按顺序执行多个 (Python) 脚本，每个脚本都在各自的窗口中，并在完成后保持所有这些窗口打开？现在，我的批次是这样的：

python script1
start python script2
pause/cmd

但只有父窗口保持打开状态。

谢谢。

环境： Windows XP/Vista

Answer 1

您可以使用start 命令打开一个新窗口（在后台使用/min）并运行命令

start "window1" /min cmd.exe /c "pause"

最后的命令，pause 可以是任何东西，只要确保全部用引号括起来

要保持窗口打开，您应该将内容放在批处理脚本中，并在最后一条语句中暂停

Answer 2

如果您只有两个脚本，那么您的想法是正确的，只是语法错误：

start cmd.exe /k "python script1.py & start cmd.exe /k python script2.py"

如果您需要窗口标题：

start "Window1" cmd.exe /K "python script1.py & start "window2" cmd.exe /K python script2.py"

脚本多于两个，您将不得不求助于更复杂的东西。以下 .cmd 文件可以解决问题：

@echo off
if "%~1" == "recurse" goto runScript%~2

start "Window1" cmd /k "%~f0 recurse 1"
exit /b 0

:runScript1
python script1.py
start "Window2" cmd /k "%~f0 recurse 2"
exit /b 0

:runScript2
python script2.py
start "Window3" cmd /k "%~f0 recurse 3"
exit /b 0

:runScript3
python script3.py
exit /b 0

这可以扩展到任意数量的脚本或命令，脚本具有任意参数等。如果您希望 cmd 窗口只是暂停，并在您按下某个键时消失：

@echo off
if "%~1" == "recurse" goto runScript%~2

start "Window1" cmd /c "%~f0 recurse 1"
exit /b 0

:runScript1
python script1.py
start "Window2" cmd /c "%~f0 recurse 2"
pause
exit /b 0

:runScript2
python script2.py
start "Window3" cmd /c "%~f0 recurse 3"
pause
exit /b 0

:runScript3
python script3.py
pause
exit /b 0

如果您希望它们在最后一个窗口上按一个键立即终止：

@echo off
if "%~1" == "recurse" goto runScript%~2

start "Window1" cmd /c "%~f0 recurse 1"
exit /b 0

:runScript1
python script1.py
start "Window2" /wait cmd /c "%~f0 recurse 2"
exit /b 0

:runScript2
python script2.py
start "Window3" /wait cmd /c "%~f0 recurse 3"
exit /b 0

:runScript3
python script3.py
pause
exit /b 0

所以，对于脚本的行为，您有很多选择。

Answer 3

[to] 在各自的窗口中按顺序执行多个 (Python) 脚本，并在完成时保持所有这些窗口打开

#!/usr/bin/env python
"""Continuation-passing style (CPS) script.

Usage:

   $ python cps.py script1.py arg1 arg2 -- script2.py a b c -- script3.py ...
"""
import platform
import sys
from subprocess import call

if len(sys.argv) < 2:
    sys.exit() # nothing to do

# define a command that starts new terminal
if platform.system() == "Windows":
    new_window_command = "cmd.exe /c start cmd.exe /c".split()
else:  #XXX this can be made more portable
    new_window_command = "x-terminal-emulator -e".split()

# find where script args end
end = sys.argv.index('--') if '--' in sys.argv else len(sys.argv)

# call script; wait while it ends; ignore errors
call([sys.executable] + sys.argv[1:end])

# start new window; call itself; pass the rest; ignore errors
rest = sys.argv[end+1:]
if rest:
    call(new_window_command + [sys.executable, sys.argv[0]] + rest)

print("Press Enter to exit") #NOTE: to avoid raw_input/input py3k shenanigans
sys.stdin.readline()

它支持在命令行上提供的尽可能多的脚本及其参数。

如果您不为脚本使用参数；你可以简化用法：

$ python cps.py script1.py script2.py script3.py

注意：脚本之间没有--。这种情况下需要修改代码：

• 设置end = 2
• 和rest = sys.argv[end:]（注：没有+1）