复制文本文件中的最后一段

Question

我有兴趣编写一个批处理脚本，它将最终文本块复制到一个包含许多其他文本块的 .txt 文件中。想想脚本执行的日志文件，但没有任何一致的内容或长度。每个条目由一个空行分隔。

所以对于下面的文档，我只想选择并复制最后一段：

Lorem ipsum dolor sit amet，consectetur adipiscing elit，sed do eiusmod tempor incididunt ut labore et dolore magna aliqua。

Ut enim ad minim veniam, quis nostrud exercitation ullamco laboris nisi ut aliquip ex ea commodo consequat。

Duis aute irure dolor in reprehenderit in voluptate velit esse cillum dolore eu fugiat nulla pariatur。 Exceptioneur sint occaecat cupidatat non proident, sunt in culpa qui officia deserunt mollit anim id est laborum。

文本本身的长度可能不同。我需要的唯一可靠指标是文档中最后一个空白行之后的所有内容——在这种情况下，“Duis aute...”之后的所有内容

我认为脚本的大纲会是这样的，但我对批处理一点也不熟悉。非常感谢您提供的任何帮助！

SET FOO
FOR /F "delims=" %%G IN (somefile.txt) DO
(IF "%%G"=="" (SET FOO="" )
ELSE (SET FOO==%%G + %FOO%))
ECHO %FOO%>whatever.txt

Answer 1

@echo off
setlocal

rem Get the line number of the last empty line
for /F "delims=:" %%a in ('findstr /N "^$" somefile.txt') do set "skip=skip=%%a"

rem Show all lines after it
for /F "%skip% delims=" %%a in (somefile.txt) do echo %%a

Answer 2

你可以这样做：

@echo off
setlocal EnableDelayedExpansion
SET "FOO="
type "file.txt" > "file.txt.tmp"
for /f "tokens=1* delims=:" %%A in ('findstr /n "^" "file.txt.tmp"') do if [%%B]==[] (SET "FOO=") else (SET "FOO=!FOO!%%B")
del "file.txt.tmp"
>filepara.txt echo %FOO%

这只有一个缺点，它不会将原始段落的换行符回显到文本文件中。

编辑：

我找到了一种方法来保留换行符，方法是创建一个包含换行符的变量：

@echo off
setlocal EnableDelayedExpansion
set LF=^


SET "FOO="
type "file.txt" > "file.txt.tmp"
for /f "tokens=1* delims=:" eol=¬ %%A in ('findstr /n "^" "file.txt.tmp"') do if [%%B]==[] (SET "FOO=") else (SET "FOO=!FOO!%%B!LF!")
del "file.txt.tmp"
>temp.txt echo !FOO!
more temp.txt > paragraph.txt
del temp.txt

注意：你需要设置 LF 之后的两个空行才能工作！