如何在 Perl 中交换两个连续的行？

Question

我有这部分代码用于编辑提示表，如果找到，我不知道如何反转两个连续的行：

/^TITLE.*?"$/  
/^PERFORMER.*?"$/

倒转

/^PERFORMER.*?"$/  
/^TITLE.*?"$/  

在我的情况下，解决方案是什么？

use strict; 
use warnings; 
use File::Find; 
use Tie::File;


my $dir_target = 'test';

find(\&c, $dir_target);        
sub c {  
   /\.cue$/ or return;

   my $fn = $File::Find::name;

   tie my @lines, 'Tie::File', $fn or die "could not tie file: $!"; 
        for (my $i = 0;  $i < @lines; $i++) {
             if ($lines[$i] =~ /^REM (DATE|GENRE|REPLAYGAIN).*?$/) {
                  splice(@lines, $i, 3);
             }
     if ($lines[$i] =~ /^\s+REPLAYGAIN.*?$/) {
                  splice(@lines, $i, 1);
             }
        }

   untie @lines; 
}

Answer 1

这似乎有点矫枉过正，但看到您的文件不是很大，我很想利用以下单行代码（从命令行或通过system 调用）。

one-liner 的工作原理是一次性将所有的行都吞掉，然后将其余的工作留给正则表达式替换，这会翻转行的顺序。

如果你使用 *nix：

perl -0777 -i -ne 's/(TITLE.*?")\n(PERFORMER.*?")/$2\n$1/g' file1 file2 ..

如果您使用的是 Windows，则需要创建现有文件的备份：

perl -0777 -i.bak -ne "s/(TITLE.*?\")\n(PERFORMER.*?\")/$2\n$1/g" file1 file2 ..

说明

命令开关（请参阅perlrun 了解更多信息）

• -0777（八进制数）强制执行文件吸食行为
• -i 启用就地编辑（无需splice-'n'-dice！）。 Windows 系统要求您提供备份扩展，因此额外的 .bak
• -n 循环遍历文件中的所有行（尽管由于您将它们吞入其中，Perl 将每个文件的内容视为一行）
• -e 允许 Perl 识别命令行中的代码

正则表达式

• 替换正则表达式捕获所有出现的TITLE 行、连续的PERFORMER 行，并将其分别存储在变量$1 和$2 中。替换正则表达式然后翻转两个变量的顺序，用换行符分隔。

文件名参数

• 您可以使用 *nix 来提供相关目录的文件名，但我将把它留给其他人来解决，因为我对 Unix 管道还不太熟悉（请参阅John Siracusa answer 了解更多信息指导）。

不过，在您尝试这些单行代码之前，我会为您的文件创建一个备份。

Answer 2

好吧，既然您要绑定到一个数组中，我只需检查 $lines[$i] 和 $lines[$i+1]（只要 +1 地址存在），如果前者匹配​​ TITLE 和后者 PERFORMER ，交换它们。除非即使它们不是连续的，您也可能需要转置它们？？

如果您知道它们将是连续的，这里有一个选项（这个 sn-p 将进入您的 for 循环，可能在 REM 检查线上方）：

if ($i < $#lines and $lines[$i] =~ /^TITLE.*?"$/
                 and $lines[$i+1] =~ /^PERFORMER.*?$/) {
    my $tmp = $lines[$i];
    $lines[$i] = $lines[$i+1];
    $lines[$i+1] = $tmp;
}

另一种选择（无论连续性如何都可以工作，并且可以说更优雅）是

use List::MoreUtils qw(first_index);

（在顶部，与您的其他use 语句一起）然后执行（在&c 内，但在for 循环之外）：

my $title_idx = first_index { /^TITLE.*?"$/ } @lines;
my $performer_idx = first_index { /^PERFORMER.*?"$/ } @lines;

if($title_idx >= 0 and $performer_idx >= 0 and $title_idx < $performer_idx)
{
    # swap these lines:
    ($lines[$title_idx],$lines[$performer_idx]) =
        ($lines[$performer_idx],$lines[$title_idx]);
}

这就是你所追求的吗？