为所有源文件添加自动标题注释

Question

我有一种在函数前后编写 cmets 的标准化方式。 例如，在声明我编写的任何函数之前，

 !---------------------------
 !  NAME_OF_FUNC           (no)
 !---------------------------

其中 no 是包含多个函数的给定文件中的第 n 个函数。 我知道一个函数例如以（Fortran 约定）子程序NAME_OF_SUB 或函数NAME_OF_FUNC 开头。因此，我的最终结果将是

 !---------------------------
 !  NAME_OF_FUNC           (no)
 !---------------------------
 function NAME_OF_FUNC(...)

 end function 
 !---------------------------

有人可以举例说明如何编写 bash 脚本或任何其他脚本语言的代码，该代码可以遍历我的所有源文件和我刚刚展示的标准约定吗？

Answer 1

这是一个 Perl 的例子。它在覆盖之前不进行备份（我建议您尝试改进此脚本并添加备份功能）。它也不添加子程序结束标记。但是添加该功能很容易，请尝试。它还假设您要修改当前目录及其所有子目录中的所有*.f95 文件：

use feature qw(say state);
use strict;
use warnings;
use File::Find::Rule;

my @files = File::Find::Rule->new->name('*.f95')->in('.');

for my $fn (@files) {
    open ( my $fh, '<', $fn ) or die "Could not open file '$fn': $!";
    my $txt = do {local $/; <$fh>};
    close $fh;
    process_txt( \$txt );
    save_txt( $fn, \$txt );
}

sub save_txt {
    my ( $fn, $txt ) = @_;

    open ( my $fh, '>', $fn ) or die "Could not open file '$fn': $!";
    print $fh $$txt;
    close $fh;
}

sub process_txt {
    my ( $txt ) = @_;

    my $i = 1;
    $$txt =~ s/^(.*(?i:function|subroutine)\s+)([a-zA-Z_]+)(\s*\(.*$)/
      do_substitution($1, $2, $3, $i++)/egmx;
}

sub do_substitution {
    my ( $head, $name, $end, $i ) = @_;

    my $line = $head . $name . $end;
    $line =~ s/\s+$//;
    my $N = length $line;
    my $cline = '!' . '-' x $N;
    my $mline = '!  ' . $name;
    my $snum = "($i)";
    my $M = (length $mline) + (length $snum);
    my $mspc = ($N > $M) ? (' ' x ($N-$M)) : '  ';
    $mline = $mline . $mspc . $snum;
    my $new_txt = join "\n", $cline, $mline, $cline, $line;
    return $new_txt;
}