如果前一行与另一个文本匹配，则替换文件中的文本

Question

我的文件如下所示：

FooBarA
foo bar
foo = bar
FooBarB
foo bar
foo = bar
FooBarC
foo bar
foo = bar
...

我想做的是编写一个脚本来替换foo = bar 中的bar，但前提是它属于FooBarB。所以在上面的例子中，应该只替换所有foo = bar 行中的第二个bar。

我玩过sed，但我就是做不好。我还想避免安装任何不一定预先安装在系统上的工具（我在 Mac OS 上），因为其他团队成员也会使用该脚本。

Answer 1

这可能对你有用（GNU sed）：

sed '/FooBarB/{:a;n;/^$/b;/foo = bar/!ba;s//foo = baz/}' file

匹配字符串FooBarB并开始循环。

取出下一行并研究它。

如果该行为空，则该节完成，因此跳出循环。

如果该行不包含字符串foo = bar，则取出下一行并继续循环。

否则，用新值替换bar 并结束循环。

---

替代方案（可能适用于 macOS 用户？）：

sed -e '/FooBarB/{:a' -e 'n;/^$/b;/foo = bar/!ba;s//foo = baz/;}' file

---

由于 OP 将输入数据更改为问题的另一个解决方案：

sed '/FooBar/h;G;/FooBarB/s/foo = bar/foo = baz/;P;d' file

Answer 2

在每个 Unix 机器上的任何 shell 中使用任何 awk：

$ awk -v tgt='FooBarB' -v val='whatever'  '
    NF==1{tag=$0} (NF>1) && (tag==tgt) && sub(/=.*/,"= "){$0=$0 val}
1' file
FooBarA
foo bar
foo = bar
FooBarB
foo bar
foo = whatever
FooBarC
foo bar
foo = bar

Answer 3

使用sed（使用 macOS 的 sed 和 GNU sed 测试）的一种方法是：

replace.sed

#!/usr/bin/env sed -Ef

/FooBarB/,/^FooBar/ {
  s/(foo[[:space:]]*=[[:space:]]*).+/\1new-value/
}

它的作用如下：

1. /FooBarB/,/^FooBar/ 匹配一系列行，其中第一行匹配正则表达式/FooBarB/，最后一行匹配正则表达式/^FooBar/（这是下一个“组”的开始）。两个正则表达式之间的逗号是sed中范围匹配的语法。

2. s/(foo[[:space:]]*=[[:space:]]*).+/\1new-value/ — [s] 替换（在匹配的行范围内）匹配正则表达式 (foo[[:space:]]*=[[:space:]]*).+ 和 \1new-value，其中 \1 引用搜索正则表达式中的第一个捕获组。搜索正则表达式查找 foo 后跟可选空格，然后是 = 符号，然后是空格，然后是其他任何内容，在您的情况下是旧值。

您可以在一行中完成所有操作，但我想展示一个更易于理解的版本（就sed 而言，无论如何）：

sed -E '/FooBarA/,/^FooBar/s/(foo[[:space:]]*=[[:space:]]*).+/\1new-value/' temp.md 

Answer 4

作为参考，GNU awk 变体：

awk -v v="newvalue" 'BEGIN{FS=OFS="\n";RS=ORS="\n\n"}$1=="FooBarB"{$3="foo = " v}1' file

通过使用选项-v，变量v 保存想要的字符串。

BEGIN 语句将输入、输出字段分隔符、输入和输出记录分隔符分别设置为一个和两个回车。
这样，一条记录就由包含模式Foobar[ABC] 的多行块组成。

最后一条语句通过重写第三行来设置新值。