Visual Basic 函数的变量声明错误

Question

我是编码新手，刚刚将我的专业从 EE 转到 IT - 在 Visual Basic 函数方面遇到了问题。我认为我的错误是在函数上声明变量的某个地方，但我不完全确定。该程序应该将在医院度过的天数乘以我声明的常数 = 350，并将所有杂项费用添加到该数字，但我返回 0。谁能帮我找出错误？

Visual Basic 代码：

Const decStay_Rate As Decimal = 350

    Private decLength As Integer
    Private decMedication As Decimal
    Private decSurgical As Decimal
    Private decLab As Decimal
    Private decPhysical As Decimal
    Private decTotalStayPrice As Decimal
    Private decTotalMiscCharges As Decimal

    Private decTotal As Decimal
    Dim decStay As Decimal


    Function validateInputField() As Boolean
        If Not Decimal.TryParse(txtLength.Text, decLength) Then
            MessageBox.Show("Stay Length must be numeric")
        End If
        If Not Decimal.TryParse(txtMedication.Text, decMedication) Then
            MessageBox.Show("Medication cost must be numeric")
        End If
        If Not Decimal.TryParse(txtSurgical.Text, decSurgical) Then
            MessageBox.Show("Surgical cost must be numeric")
        End If
        If Not Decimal.TryParse(txtLabFees.Text, decLab) Then
            MessageBox.Show("Lab fees must be numeric")
        End If
        If Not Decimal.TryParse(txtPhysicalRehab.Text, decPhysical) Then
            MessageBox.Show("Physical Rehab cost must be numeric")
        End If

        Return True
    End Function

    Function CalcStayCharges(ByVal decLength As Decimal) As Decimal
        Dim decTotalStayPrice As Decimal
        decTotalStayPrice = decLength * decStay_Rate
        Return decTotalStayPrice
    End Function

    Function CalcMiscCharges(ByVal decmedication As Decimal, ByVal decsurgical As Decimal, ByVal decLab As Decimal, ByVal decPhysical As Decimal) As Decimal
        Dim decTotalMiscCharges As Decimal
        decTotalMiscCharges = decmedication + decsurgical + decLab + decPhysical
        Return decTotalMiscCharges
    End Function

    Private Function CalcTotalCharges(ByVal decTotalStayPrice As Decimal, ByVal decTotalMiscCharges As Decimal) As Decimal
        Dim decTotalCharge As Decimal
        decTotalCharge = decTotalStayPrice + decTotalMiscCharges
        Return decTotalCharge
    End Function
    Private Sub btnClear_Click(sender As Object, e As EventArgs) Handles btnClear.Click

        txtLabFees.Text = String.Empty
        txtLength.Text = String.Empty
        txtMedication.Text = String.Empty
        txtPhysicalRehab.Text = String.Empty
        txtSurgical.Text = String.Empty

    End Sub

    Private Sub btnExit_Click(sender As Object, e As EventArgs) Handles btnExit.Click
        Me.Close()
    End Sub

    Private Sub btnCalc_Click(sender As Object, e As EventArgs) Handles btnCalc.Click
        Dim decTotal As Decimal

        lblOutput.Text = String.Empty
        If validateInputField() Then
            decTotal = CalcTotalCharges(decTotalStayPrice, decTotalMiscCharges)

            lblOutput.Text = decTotal.ToString("c")
        End If
    End Sub

谢谢， 埃里克

Answer 1

首先，您不需要Decimal.TryParse(txtLength.Text, decLength) 来检查它是否为数字。你可以使用IsNumeric 所以IsNumeric(txtLength.Text)。如果成功，Decimal.TryParse 会将值从 txtLength.Text 分配给 decLength，但您不需要这样做。

我会将validateInputField 的方法更改为：

Function validateInputField() As Boolean
    If Not IsNumeric(txtLength.Text) Then
        MessageBox.Show("Stay Length must be numeric")
        Return False
    End If
    If Not IsNumeric(txtMedication.Text) Then
        MessageBox.Show("Medication cost must be numeric")
        Return False
    End If
    If Not IsNumeric(txtSurgical.Text) Then
        MessageBox.Show("Surgical cost must be numeric")
        Return False
    End If
    If Not IsNumeric(txtLabFees.Text) Then
        MessageBox.Show("Lab fees must be numeric")
        Return False
    End If
    If Not IsNumeric(txtPhysicalRehab.Text) Then
        MessageBox.Show("Physical Rehab cost must be numeric")
        Return False
    End If

    Return True
End Function

我会删除所有这些，因为它们会让您感到困惑：

Private decLength As Integer
Private decMedication As Decimal
Private decSurgical As Decimal
Private decLab As Decimal
Private decPhysical As Decimal
Private decTotalStayPrice As Decimal
Private decTotalMiscCharges As Decimal

Private decTotal As Decimal
Dim decStay As Decimal

然后您需要将正确的值传递给方法CalcTotalCharges：

decTotal = CalcTotalCharges(value1, value2)

你可能在绕道而行：

Private Sub btnCalc_Click(sender As Object, e As EventArgs) Handles btnCalc.Click
    Dim decTotal As Decimal

    lblOutput.Text = ""
    If validateInputField() Then
        decTotal = CalcTotalCharges(CalcStayCharges(CDec(txtLength.Text)), CalcMiscCharges(CDec(txtMedication.Text), CDec(txtSurgical.Text), CDec(txtLabFees.Text), CDec(txtPhysicalRehab.Text)))

        lblOutput.Text = decTotal.ToString("c")
    End If
End Sub