如何比较文件 w.r.t 关键字文件并将第 3 列的不匹配字符串替换为关键字文件第 3 列中的正确字符串

Question

我想在 keyword_file 中搜索 search_file 的每一行并打印一个 output_file 用提取的正确字符串替换该行的不正确字符串来自 keyword_file。此外，如果缺少第 3 列的条目很少，则应警告用户，这些条目在 keyword_file 中不存在并且在 search_file 中具有（例如，“ggg coms”在文件）

注意，这里 keyword_file 可能包含与 search_file 不同的行数。例如： 搜索文件

aaa coms 123
bbb coms 234
ccc 
ddd coms 456
eez coms 789
fkk coms 987
ggg coms   
hhh coms 989
....

keyword_file

aaa coms 789
bbb coms 234
ccc coms 878
ddd coms 456
ttt coms 654 
eee coms 789

输出

aaa coms 789
bbb coms 234
ccc coms 878
ddd coms 456
eez coms 789
fkk coms 987
hhh coms 989
....

我尝试了以下 awk 命令，但它无法在 输出 中保留 search_file 的第 1 列条目。

awk 'FNR==NR{a[$1]=$0} FNR!=NR&&a[$1]{print $1,$2,$3}' search_file keyword_file

非常感谢您的帮助:)

Answer 1

您能否仅根据所示示例尝试以下、编写和测试。

awk '
{
  key=$1
}
FNR==NR{
  a[key]=$3
  next
}
(key in a){
  $0=key OFS $2 OFS a[key]
}
1
'  keyword_file  search_file

说明：为上述添加详细说明。

awk '                                ##Starting awk program from here.
{
  key=$1                             ##Run this command on each line of Input_file and create variable key with value of 1st field.
}
FNR==NR{                             ##Checking condition if FNR==NR which will be TRUE when keyword_file is being read.
  a[key]=$3                          ##Creating array a with index key and value of 3rd field here.
  next                               ##next will skip all further statements from here.
}
(key in a){                          ##Checking condition if key is present in array a then do following.
  $0=key OFS $2 OFS a[key]           ##Setting value of key OFS 2nd field OFS array a value with index key here.
}
1                                    ##1 will print edited/non-edited values for all lines.
'  keyword_file  search_file         ##Mentioning Input_file names here.

为什么 OP 的代码不起作用：您很接近，您只打印了 Input_files 中第一个和第二个字段共同的行，所以我所做的是：而检查两个 Input_files 中字段是否通用的条件，然后使用新的最后一个值重新创建该行，然后通过提及 1 打印当前（已编辑/未编辑）行。