Agda 类型检查和交换性 / + 的关联性

Question

由于Nat 的_+_ 操作通常在第一个参数中递归定义，因此类型检查器知道i + 0 == i 显然不是微不足道的。然而，当我在固定大小的向量上编写函数时，我经常遇到这个问题。

一个例子：我如何定义一个 Agda 函数

swap : {A : Set}{m n : Nat} -> Vec A (n + m) -> Vec A (m + n)

将第一个n 值放在向量的末尾？

因为在 Haskell 中一个简单的解决方案是

swap 0 xs     = xs
swap n (x:xs) = swap (n-1) (xs ++ [x])

我在 Agda 中类似地尝试过这样的：

swap : {A : Set}{m n : Nat} -> Vec A (n + m) -> Vec A (m + n)    
swap {_} {_} {zero} xs          = xs 
swap {_} {_} {suc i} (x :: xs)  = swap {_} {_} {i} (xs ++ (x :: []))

但是类型检查器失败并显示消息（与上述swap-Definition 中的{zero}-case 相关）：

.m != .m + zero of type Nat
when checking that the expression xs has type Vec .A (.m + zero)

那么，我的问题是：如何教 Agda，m == m + zero？以及如何在 Agda 中编写这样的swap 函数？

Answer 1

教 Agda m == m + zero 并不难。例如，使用等式证明的标准类型，我们可以写出这样的证明：

rightIdentity : (n : Nat) -> n + 0 == n
rightIdentity zero = refl
rightIdentity (suc n) = cong suc (rightIdentity n)

然后我们可以告诉 Agda 使用 rewrite 关键字来使用这个证明：

swap : {A : Set} {m n : Nat} -> Vec A (n + m) -> Vec A (m + n)    
swap {_} {m} {zero} xs rewrite rightIdentity m = xs 
swap {_} {_} {suc i} (x :: xs) = ?

但是，为第二个等式提供必要的证明要困难得多。一般来说，尝试使您的计算结构与您的类型的结构相匹配是一个更好的主意。这样一来，您就可以少做很多定理证明（或者在这种情况下没有）。

例如，假设我们有

drop : {A : Set} {m : Nat} -> (n : Nat) -> Vec A (n + m) -> Vec A m
take : {A : Set} {m : Nat} -> (n : Nat) -> Vec A (n + m) -> Vec A n

（两者都可以在没有任何定理证明的情况下定义），Agda 会很高兴地接受这个定义，而不用大惊小怪：

swap : {A : Set} {m n : Nat} -> Vec A (n + m) -> Vec A (m + n)
swap {_} {_} {n} xs = drop n xs ++ take n xs