无法在特定网站上执行自动搜索

Question

最近我正在学习使用 excel 宏在网站上进行搜索。我已经阅读了几个论坛主题，并想出了下面的代码。但是，当我到达该行时出现错误

SearchBox(0).Value = SearchString

我试图删除 (0) 但也出现了另一个错误。该代码在其他网站上运行良好。我应该如何改变它们以适应这个网站？

附：我也想知道点击搜索按钮的方法。

Sub Searchstockcode()

    Dim SearchString As String

    SearchString = "700"

    Set ie = CreateObject("InternetExplorer.Application")
    With ie

    ie.Visible = True
    End With

    ie.Navigate "http://www.hkexnews.hk/listedco/listconews/advancedsearch/search_active_main.aspx"

    While ie.ReadyState <> 4

    DoEvents

    Wend


    Dim SearchBox As Object

    Set SearchBox = ie.Document.GetElementsByName("ct100$txt_stock_code")

    SearchBox(0).Value = SearchString


    Dim SearchButton As Object

    Set SearchButton = ie.Document.GetElementsByName


End Sub

Answer 1

我不知道您的名称选择问题是否是由于元素具有两个名称属性，但这似乎是可能的。

您可以使用以下内容。

对于搜索框，我使用它的 id 来定位元素。这通常在文档上是唯一的，也是最快的选择器方法。

对于搜索按钮，我使用了

的 CSS 属性 + 值选择器

[src*='/image/search.gif']

这将通过其值定位元素的src 属性[]。 * 表示包含。选择器会查找在其值中包含 /image/search.gif 的 src 属性。

你可以在这里观察属性：

Option Explicit
Sub Searchstockcode()

    Dim SearchString As String, SearchBox As Object, SearchButton As Object, ie As Object

    SearchString = "700"

    Set ie = CreateObject("InternetExplorer.Application")

    ie.Visible = True

    ie.navigate "http://www.hkexnews.hk/listedco/listconews/advancedsearch/search_active_main.aspx"

    While ie.Busy Or ie.readyState < 4: DoEvents: Wend

    Set SearchBox = ie.document.getElementById("ctl00_txt_stock_code")
    SearchBox.Value = SearchString

    Set SearchButton = ie.document.querySelector("[src*='/image/search.gif']")
    SearchButton.Click

    While ie.Busy Or ie.readyState < 4: DoEvents: Wend

    Stop '<==Delete me
    'other code
    ie.Quit
End Sub