是否可以获得特定 Perl 类的所有有效方法？

Question

是否可以获得特定 Perl 类的所有有效方法？

我正在尝试操作一个类的符号表并获取它的所有方法。我发现我可以通过$obj->can($method) 将子例程与非子例程分开，但这并不完全符合我的想法。

以下返回：

subroutine, Property, croak, Group, confess, carp, File

但是，subroutine 不是方法，（只是一个子程序），croak、confess 和 carp 都被导入到我的包中。

我真正想打印的是：

Property,Group, File

但我会接受：

subroutine, Property,Group, File

下面是我的程序：

#! /usr/bin/env perl

use strict;
use warnings;
use feature qw(say);

my $sections = Section_group->new;
say join ", ", $sections->Sections;

package Section_group;
use Carp;

sub new     {
    return bless {}, shift;
}

sub Add {
    my $self                = shift;
    my $section             = shift;
}

sub Sections {
    my $self                = shift;

    my @sections;
    for my $symbol ( keys %Section_group:: ) {
        next if $symbol eq "new";   # This is a constructor
        next if $symbol eq "Add";   # Not interested in this method
        next if $symbol eq "Sections";      # This is it's own method
        push @sections, $symbol if $self->can($symbol);
    }

    return wantarray ? @sections : \@sections;
}

sub subroutine {
    my $param1              = shift;
    my $param2              = shift;
}

sub Group {
    my $self                = shift;
    my $section             = shift;
}

sub File {
    my $self                = shift;
    my $section             = shift;
}

sub Property {
    my $self                = shift;
    my $section             = shift;
}

Answer 1

这是相当微不足道的。我们只想保留那些最初在我们的包中定义的子名称。每个 CV（代码值）都有一个指向定义它的包的指针。感谢B，我们可以检查一下：

use B ();

...

if (my $coderef = $self->can($symbol)) {
  my $cv = B::svref_2object $coderef;
  push @sections, $symbol if $cv->STASH->NAME eq __PACKAGE__;
}

# Output as wanted

也就是说，我们使用svref_2object 执行自省。这将返回一个表示内部 perl 数据结构的 Perl 对象。

如果我们查看 coderef，我们会得到一个 B::CV object，它代表内部的 CV。 CV 中的 STASH 字段指向定义它的 Stash。如您所知，Stash 只是一个特殊的哈希（内部表示为HV），因此$cv->STASH 返回一个B::HV。如果 HV 是 Stash，而不是常规哈希，HV 的 NAME 字段包含 Stash 的完全限定包名称。

现在我们有了我们需要的所有信息，并且可以将想要的包名称与 coderef 的存储名称进行比较。

当然，这是简化的，您将希望通过@ISA 进行一般类的递归。

---

没有人喜欢被污染的命名空间。值得庆幸的是，有些模块可以从 Stash 中删除外来符号，例如namespace::clean。当您调用的所有子程序的 CV 在编译时已知时，这没有问题。

Answer 2

你想做什么？为什么一个类如何定义或实现它响应的方法很重要？

Perl 是一种动态语言，这意味着方法根本不必存在。使用AUTOLOAD，方法可能非常好并且可调用，但永远不会出现在符号表中。一个好的接口可以让can 在这些情况下工作，但在某些情况下，类或对象可能会决定以 false 响应。

Package::Stash 模块可以帮助您在特定命名空间中找到已定义的子例程，但正如您所说，它们可能不在同一个文件中定义。类中的方法可能来自继承的类。如果你关心他们来自哪里，那你可能做错了。