计算着色器共享内存包含工件答案

【问题标题】：Compute shader shared memory contains artifacts计算着色器共享内存包含工件
【发布时间】：2017-05-01 18:02:53
【问题描述】：

我一直在尝试编写一个通用的计算着色器高斯模糊实现。

它基本上可以工作，但是它包含的伪影会在每一帧都发生变化，即使场景是静态的也是如此。在过去的几个小时里，我一直在尝试调试它。我已经尽可能确保不超过界限，展开所有循环，用常量替换制服，但工件仍然存在。

我已经在 3 台不同的机器/GPU（2 台 nvidia、1 台英特尔）上使用工件测试了原始代码，它们都产生了相同的结果。使用纯 C++ 代码向前和向后执行的工作组模拟代码执行的展开/恒定版本不会产生这些错误。

通过分配 [96][96] 而不是 [16][48] 的共享数组，我可以消除大部分工件。

这让我想到我错过了一个逻辑错误，因此我设法生成了一个非常简单的着色器，它仍然会在较小的范围内产生错误，如果有人能指出原因，我将不胜感激。我检查了很多文档，找不到任何不正确的地方。

分配了一个 16x48 浮点数的共享数组，这是 3072 字节，大约是最小共享内存限制的 10%。

着色器在 16x16 工作组中启动，因此每个线程将写入 3 个唯一位置，并从单个唯一位置读回

然后将纹理渲染为 HSV，其中 0-1 之间的值将映射到色相 0-360（红-青-红），超出范围的值将是红色。

#version 430
//Execute in 16x16 sized thread blocks
layout(local_size_x=16,local_size_y=16) in;
uniform layout (r32f) restrict writeonly image2D _imageOut;
shared float hoz[16][48];
void main () 
{
    //Init shared memory with a big out of bounds value we can identify
    hoz[gl_LocalInvocationID.x][gl_LocalInvocationID.y] = 20000.0f;
    hoz[gl_LocalInvocationID.x][gl_LocalInvocationID.y+16] = 20000.0f;
    hoz[gl_LocalInvocationID.x][gl_LocalInvocationID.y+32] = 20000.0f;
    //Sync shared memory
    memoryBarrierShared();
    //Write the values we want to actually read back
    hoz[gl_LocalInvocationID.x][gl_LocalInvocationID.y] = 0.5f;
    hoz[gl_LocalInvocationID.x][gl_LocalInvocationID.y+16] = 0.5f;
    hoz[gl_LocalInvocationID.x][gl_LocalInvocationID.y+32] = 0.5f;
    //Sync shared memory
    memoryBarrierShared();
    //i=0,8,16 work
    //i=1-7,9-5,17 don't work (haven't bothered testing further
    const int i = 17;
    imageStore(_imageOut, ivec2(gl_GlobalInvocationID.xy), vec4(hoz[gl_LocalInvocationID.x][gl_LocalInvocationID.y+i]));
    //Sync shared memory (can't hurt)
    memoryBarrierShared();
}

以大于 8x8 的启动尺寸启动此着色器会在图像的受影响区域产生伪影。

glDispatchCompute(9, 9, 0); glMemoryBarrier(GL_SHADER_IMAGE_ACCESS_BARRIER_BIT);

我必须断点和步进帧来捕捉它，大约需要 14 帧

glDispatchCompute(512/16, 512/16, 0);//Full image is 512x512 glMemoryBarrier(GL_SHADER_IMAGE_ACCESS_BARRIER_BIT);

同样，当以 60 FPS (vsync) 运行时，我不得不断点和步进帧来捕捉这一点，伪影更频繁/同时出现。

【问题讨论】：

标签： opengl glsl opengl-4 compute-shader

【解决方案1】：

memoryBarrierShared();

不，这只会使写入对其他调用可见。如果您希望能够从其他调用的数据中读取数据，则必须确保所有写入都已实际发生。

这是通过the barrier function 完成的。应该在memoryBarrierShared 之后调用。

【讨论】：