如何将tableau中的ifnull语句转换为powerbi dax？

Question

我正在处理从 tableau 到 power bi 的仪表板转换。卡在 tableau 中的计算维度需要使用 dax 转换为 powerbi！

通过替换 tableau 中的 IFNULL 语句。我已经尝试使用 IF 语句在 dax 中使用 ISBLANK 参数，该语句应该检查该字段是否返回空值。我对 dax 的了解是有限的，我想这个问题真的很简单，但我坚持了好几个小时。

需要转换成powerbi的tableau代码：

if LEFT([Supplier Code],1) = "E" then "Employees Claims" else 
IF 
IFNULL(IFNULL([ASL Supplier (SWPS)],IFNULL([Supplier Name],IFNULL([Vendor],[Supplier Code]))),'Not Define')= 'N/A'
THEN IFNULL([Vendor],[Supplier Name]) ELSE
IFNULL(IFNULL([ASL Supplier (SWPS)],IFNULL([Supplier Name],IFNULL([Vendor],[Supplier Code]))),'Not Define') 
END
END

我尝试过的 Power bi 代码：

Supplier (swps) = IF(LEFT([Supplier Code],1) = "E", "Employee Claims",
IF(
IF(ISBLANK(V_FIPnLDashboard_Tne[ASL Supplier (SWPS)]),ISBLANK(V_FIPnLDashboard_Tne[Supplier Name]),ISBLANK(V_FIPnLDashboard_Tne[Supplier Code])),"Not Define") = "N/A")

我的代码不完整，因为我无法理解 tableau 中代码的完整分解。

画面：

if LEFT([Supplier Code],1) = "E" then "Employees Claims" else 
IF 
IFNULL(IFNULL([ASL Supplier (SWPS)],IFNULL([Supplier Name],IFNULL([Vendor],[Supplier Code]))),'Not Define')= 'N/A'
THEN IFNULL([Vendor],[Supplier Name]) ELSE
IFNULL(IFNULL([ASL Supplier (SWPS)],IFNULL([Supplier Name],IFNULL([Vendor],[Supplier Code]))),'Not Define') 
END
END

预期结果是一个维度/列，其值作为 power bi 中的给定条件。

Answer 1

IF IFNULL([ASL Supplier(SWPS)],IFNULL([Supplier(SWPS)],IFNULL([Vendor],IFNULL([Supplier Code],'Not Define')))) = 'N/A'
THEN [Supplier(SWPS)] 
ELSE IFNULL([ASL Supplier (SWPS)],IFNULL([Supplier(SWPS)],IFNULL([Vendor],IFNULL([Supplier Code],'Not Define'))))
END

Answer 2

supplier = var supplierswps = 
 `IF (
                              ISBLANK (V_FIPnLDashboard_Tne[ASL Supplier(SWPS)]),
        IF (
             ISBLANK (V_FIPnLDashboard_Tne [Supplier (SWPS)]),
            IF (
                ISBLANK ( V_FIPnLDashboard_Tne[Vendor] ),
                IF (
                    ISBLANK (V_FIPnLDashboard_Tne [Supplier Code]),"Not Define")))= "N/A",V_FIPnLDashboard_Tne[Supplier (swps)])
var supplierswpsfalse = IF(supplierswps = "Not define", TRUE(), FALSE())
        return
            if( 
               ISBLANK(V_FIPnLDashboard_Tne[ASL Supplier (SWPS)] ),
                IF (
                    ISBLANK (V_FIPnLDashboard_Tne[Supplier (SWPS)]),
                     IF(
                        ISBLANK ( V_FIPnLDashboard_Tne[Vendor] ),
                            IF (
                                ISBLANK (V_FIPnLDashboard_Tne[Supplier Code] )
                            ,"Not Define",
                            V_FIPnLDashboard_Tne[Supplier Code]
                                ),
`

                       V_FIPnLDashboard_Tne[Vendor]  

                     ),V_FIPnLDashboard_Tne[Supplier (SWPS)]
                ),V_FIPnLDashboard_TnE[ASL Supplier (SWPS)]
            )

Answer 3

在您的示例中，我发现分解 Tableau 代码的原始逻辑最有用：

• 如果供应商代码以“E”开头，则为“Employee Claims”
• 否则，
  • 按顺序检查，如果 ASL 供应商 (SWPS)、供应商名称、供应商、供应商代码 = “N/A”，则
    • 如果 Vendor 不为空，则为 Vendor
    • 其他，供应商名称
  • 否则，按顺序检查，
    • 如果 ASL 供应商 (SWPS)、供应商名称、供应商、供应商代码有值，请使用它
    • 否则，使用“未定义”

鉴于此，DAX 公式为：

Supplier (swps) =
VAR vendorOrSupplier =
    IF (
        ISBLANK ( V_FIPnLDashboard_Tne[Vendor] ),
        V_FIPnLDashboard_Tne[Supplier Name],
        V_FIPnLDashboard_Tne[Vendor]
    )
VAR firstValidField =
    IF (
        ISBLANK ( V_FIPnLDashboard_Tne[ASL Supplier (SWPS)] ),
        IF (
            ISBLANK ( V_FIPnLDashboard_Tne[Supplier Name] ),
            IF (
                ISBLANK ( V_FIPnLDashboard_Tne[Vendor] ),
                IF (
                    ISBLANK ( V_FIPnLDashboard_Tne[Supplier Code] ),
                    "Not Defined",
                    V_FIPnLDashboard_Tne[Supplier Code]
                ),
                V_FIPnLDashboard_Tne[Vendor]
            ),
            V_FIPnLDashboard_Tne[Supplier Name]
        ),
        V_FIPnLDashboard_Tne[ASL Supplier (SWPS)]
    )
VAR allBlank =
    IF ( firstValidField = "Not Defined", TRUE (), FALSE () )
RETURN
    IF (
        LEFT ( V_FIPnLDashboard_Tne[Supplier Code], 1 ) = "E",
        "Employee Claims",
        IF (
            V_FIPnLDashboard_Tne[ASL Supplier (SWPS)] = "N/A",
            vendorOrSupplier,
            IF (
                ISBLANK ( V_FIPnLDashboard_Tne[ASL Supplier (SWPS)] ),
                IF (
                    V_FIPnLDashboard_Tne[Supplier Name] = "N/A",
                    vendorOrSupplier,
                    IF (
                        ISBLANK ( V_FIPnLDashboard_Tne[Supplier Name] ),
                        IF (
                            V_FIPnLDashboard_Tne[Vendor] = "N/A",
                            vendorOrSupplier,
                            IF (
                                ISBLANK ( V_FIPnLDashboard_Tne[Vendor] ),
                                IF ( [Supplier Code] = "N/A", vendorOrSupplier, firstValidField ),
                                firstValidField
                            )
                        ),
                        firstValidField
                    )
                ),
                firstValidField
            )
        )
    )