锁定 Perl 子例程

Question

我写了一个 CGI 脚本。它的子程序之一不能同时执行。即同一用户（或黑客）同时运行两个实例）。我怎样才能避免这种情况？

我使用锁定文件做了以下解决方法，但我不确定它是否安全：

unless (-e $filelock) {
    sub_that_should_be_locked();
}


sub sub_that_should_be_locked {
    open FILE, ">", $filelock;
    flock DATAFILE, LOCK_EX;
    close FILE;

    ...Code that cannot be executed at the same time...   
    ...Code that cannot be executed at the same time...

    unlink $filelock;
}

不应该有等待/队列，并发进程不应该调用 sub_that_should_be_locked

Answer 1

您要同步的线程不应创建和删除锁定文件。

你应该确保文件存在在线程启动之前，然后子例程应该使用一个词法文件句柄来打开输入的锁文件.

这样

open my $lock_fh, '<', $lockfile or die $!;
flock $lock_fh, LOCK_EX;

作为它的第一个动作。这将暂停线程，直到它连接到队列中，之后文件将在子例程结束时隐式关闭（并释放它的锁），因为$lock_fh 超出范围

Answer 2

这不安全。由于-e 和open 之间存在时间，因此您的代码中存在竞争条件。永远不要将-e 用于锁定文件。

检查文件是否已被锁定，而不是检查文件是否存在。这是使用非阻塞flock 完成的。如果文件没有被锁定，它会返回成功，如果文件已经被锁定，它会返回错误EWOULDBLOCK。

请注意，要使其正常工作，您必须在 sub_that_should_be_locked 执行的整个过程中保持锁定。 （你的代码一得到它就释放它。）

use Fcntl qw( LOCK_EX LOCK_NB );

sub get_lock_nb {
   my ($qfn) = @_;

   open(my $fh, '+>:raw', $qfn)
      or die("Unable to open file \"$qfn\": $!\n");

   if (!flock($fh, LOCK_EX | LOCK_NB)) {
      return undef if $!{EWOULDBLOCK};
      die("Unable to lock file \"$qfn\": $!\n");
   }

   return $fh;
}

sub sub_that_should_be_locked {
   ... Mutually exclusive code ...
}

{
   my $lock = get_lock_nb("file.lock");
   sub_that_should_be_locked() if $lock;
}