从现有表创建新的 SQL Server 表

Question

我的工作是通过删除月份列并在列字段上重新创建该表分组并对小时列求和来更新数据库表。

以下是我的说明：“创建一个没有 Month 列的新 PS_StaffHours 表。通过按 (PSScnID/PSEmpID/Prd/WBSID/RatePrd) 分组并将小时数相加，将现有 PS_StaffHours 数据迁移到新表。”

现在这是我编写的表格，必须重新创建没有月份列和汇总小时列的表格：

CREATE TABLE [dbo].[PS_StaffHours]
(
    [PSScnID] [int] NOT NULL,
    [PSEmpID] [int] NOT NULL,
    [Prd] [int] NOT NULL,
    [WBSID] [int] NOT NULL,
    [RatePrd] [int] NOT NULL,
    [Month] [date] NOT NULL,
    [Hours] [decimal](16, 8) NOT NULL,

   CONSTRAINT [PK_PS_StaffHours] 
       PRIMARY KEY CLUSTERED ([PSScnID] ASC, [PSEmpID] ASC, [Prd] ASC,
                              [WBSID] ASC, [RatePrd] ASC, [Month] ASC)
                   WITH (PAD_INDEX = OFF, STATISTICS_NORECOMPUTE = OFF, 
                         IGNORE_DUP_KEY = OFF, ALLOW_ROW_LOCKS = ON, ALLOW_PAGE_LOCKS = ON) ON [PRIMARY]
) ON [PRIMARY]
GO

ALTER TABLE [dbo].[PS_StaffHours] WITH CHECK 
    ADD CONSTRAINT [FK_PS_StaffHours_PS_Scenarios] 
        FOREIGN KEY([PSScnID]) REFERENCES [dbo].[PS_Scenarios] ([PSScnID])
GO

ALTER TABLE [dbo].[PS_StaffHours] CHECK CONSTRAINT [FK_PS_StaffHours_PS_Scenarios]
GO

ALTER TABLE [dbo].[PS_StaffHours] WITH CHECK 
    ADD CONSTRAINT [FK_PS_StaffHours_PS_Staff] 
        FOREIGN KEY([PSScnID], [PSEmpID]) REFERENCES [dbo].[PS_Staff] ([PSScnID], [PSEmpID])
GO

ALTER TABLE [dbo].[PS_StaffHours] CHECK CONSTRAINT [FK_PS_StaffHours_PS_Staff]
GO

ALTER TABLE [dbo].[PS_StaffHours] WITH CHECK 
    ADD CONSTRAINT [FK_PS_StaffHours_PS_WBS] 
        FOREIGN KEY([PSScnID], [WBSID]) REFERENCES [dbo].[PS_WBS] ([PSScnID], [WBSID])
GO

ALTER TABLE [dbo].[PS_StaffHours] CHECK CONSTRAINT [FK_PS_StaffHours_PS_WBS]
GO

ALTER TABLE [dbo].[PS_StaffHours] WITH CHECK 
    ADD CONSTRAINT [CK_PS_StaffHours] CHECK ((DATEPART(day, [Month]) = (1)))
GO

ALTER TABLE [dbo].[PS_StaffHours] CHECK CONSTRAINT [CK_PS_StaffHours]
GO

EXEC sys.sp_addextendedproperty 
         @name = N'MS_Description', 
         @value = N'Restricts Month field to the 1st of every month.' , 
         @level0type = N'SCHEMA', @level0name = N'dbo',  
         @level1type = N'TABLE', @level1name = N'PS_StaffHours',  
         @level2type = N'CONSTRAINT', @level2name = N'CK_PS_StaffHours'
GO

首先，要创建新表，我认为我所要做的就是在脚本的 CREATE 部分重命名表名，然后删除 CREATE 语句中 Month 列的所有引用。我对 CREATE 脚本的看法是否正确？

现在，这是我将用于填充没有月份字段的表的脚本，但我不确定分组是否正确，因为我收到错误，因为我不是 grouping on小时列与其余部分。另外，我不确定如何处理summing 查询中的小时数。

我的代码：

SELECT c.PSScnID, c.PSEmpID, c.Prd, c.WBSID, c.RatePrd, c.Hours  
INTO dbo.NewPS_StaffHours 
FROM PS_StaffHours AS c  
GROUP BY c.PSScnID, c.PSEmpID, c.Prd, c.WBSID, c.RatePrd  
GO

Answer 1

您的第一个假设是正确的。 要按列分组并总结小时数 - 试试这个：

SELECT c.PSScnID, c.PSEmpID, c.Prd, c.WBSID, c.RatePrd, SUM(c.Hours) AS Hours
INTO dbo.NewPS_StaffHours 
FROM PS_StaffHours AS c  
GROUP BY c.PSScnID, c.PSEmpID, c.Prd, c.WBSID, c.RatePrd  
GO

听起来您要在运行选择之前创建表。 所以摆脱INTO dbo.NewPS_StaffHours。运行 create table 语句，然后 INSERT INTO newTable VALUES... SELECT