属性没有被写入，只能从 Delphi XE2 中读取

Question

我创建了自己的组件，其中包含一个 TFont 以及 适当的属性。

组件在 Public 声明中具有以下属性

property CaptionFont: TFont read fCaptionFont write SetCaptionFont;

SetCaptionFont 过程如下所示

procedure TMyComponent.SetCaptionFont(value: TFont);
begin
  fCaptionFont := value;
end;

我正在尝试使用以下代码将字体名称和字体大小分配给我的组件：

MyComponent.CaptionFont.Name := fGlobalStandardFontName;
MyComponent.CaptionFont.Size := fGlobalStandardFontSize;

但是，当在该行放置断点时

MyComponent.CaptionFont.Name := fGlobalStandardFontName;

然后点击“Trace Into(F7)”调试按钮，代码跳转到TFont代码并 完全忽略 SetCaptionFont 过程。

我希望调用 SetCaptionFont 过程。

这是怎么回事？

Answer 1

在为子属性赋值时不会调用SetCaptionFont()，因为你没有为CaptionFont属性本身赋值。

即使调用了它，您的SetCaptionFont() 也没有正确实现。您正在获取源 TFont 的所有权并泄露您的原始 TFont。您需要改用Assign() 将源TFont 值复制到现有的TFont 中。

要检测子属性值更改（包括来自Assign()），您需要将OnChange 事件处理程序分配给您的fCaptionFont 对象，例如：

constructor TMyComponent.Create(AOwner: TComponent);
begin
  inherited;
  fCaptionFont := TFont.Create;
  fCaptionFont.OnChange := CaptionFontChanged;
end;

procedure TMyComponent.SetCaptionFont(value: TFont);
begin
  fCaptionFont.Assign(value);
end;

procedure TMyComponent.CaptionFontChanged(Sender: TObject);
begin
  Invalidate;
end;

procedure TMyComponent.Paint;
begin
  // use fCaptionFont as needed...
end;

Answer 2

理解这一点的关键是赋值运算符的位置。

当您对属性使用赋值运算符时，会调用属性设置器。让属性设置器为您的属性执行的唯一方法是编写这种形式的代码：

CaptionFont := ...;

你不这样做。相反，你写：

CaptionFont.Name := ...;

这里使用CaptionFont 的getter，然后使用Name 的setter。

这就解释了为什么不调用 setter。

除此之外，您错误地实现了 setter。您的实现可能会泄漏您在构造函数中创建的对象，该对象的引用保存在FCaptionFont 中。当您分配给FCaptionFont 时，您将失去对该对象的跟踪。

类属性的约定是将设置属性的操作转换为对Assign的调用。这使得属性具有值语义而不是引用。属性值被复制。因此，setter 看起来像这样：

procedure TMyComponent.SetCaptionFont(Value: TFont);
begin
  FCaptionFont.Assign(Value);
end;