如何在 Z80 asm 中重复将两个字节写入一块 RAM

Question

我正在尝试将两个字节（颜色值）写入我的 TI-84 Plus CE-T 计算器的 VRAM，该计算器使用 Zilog eZ80 CPU。 VRAM 从 0xD40000 开始，长度为 0x25800 字节。计算器有一个名为MemSet 的内置系统调用，它用一个字节填充一块内存，但我希望它在两个不同的值之间交替并将它们存储在内存中。我尝试使用以下代码：

#include "includes\ti84pce.inc"

    .assume ADL=1
    .org userMem-2
    .db tExtTok,tAsm84CeCmp

    call  _homeup
    call  _ClrScrnFull
    ld    hl,13893632     ; = D40000, vram start
    ld    bc,153600       ; = 025800, count/vram length
j1:
    ld    (hl),31         ; set first byte
    inc   hl
    dec   bc
    jr    z,j2            ; jump to end if count==0
    ld    (hl),0          ; set second byte
    inc   hl
    dec   bc
    jr    z,j2            ; jump to end if count==0
    jp    j1              ; loop
j2:
    call  _GetKey
    call  _ClrScrnFull
    ret

我希望它从 0xD40000 开始将 31 00 31 00 31 00... 输出到内存中，但它似乎只更改了第一个字节并在这样做之后跳转到末尾。有关如何解决此问题的任何想法？

Answer 1

这不起作用：

dec   bc
jr    z,j2

只有 8 位 dec 和 inc 修改标志。可以通过正确检测bc 是否为零来解决。

这是一种无需手动循环的不同技术：

ld    hl,$D40000
ld    (hl),31
inc   hl
ld    (hl),0
dec   hl
ld    de,$D40002
ld    bc,$25800 - 2
ldir

Answer 2

请参阅底部的Update 3。

除了@harold 的回答：如果需要更快的替代方案，可以使用众所周知的 PUSH 技巧。

我不熟悉 TI-84，堆栈技巧在某些系统上可能不可接受，或者需要禁用中断。当然，您应该在上述代码之前/之后存储/恢复 SP。

更新 3： 删除了我的代码 sn-p，因为它对于 eZ80 是不正确的。 但是，感谢@DrDnar 提供的链接，这里是某人的-不是我的！ :)- 尝试将性能推到极限（是的，我知道填充 55 美元与在 31 美元和 00 美元之间交替使用不同）：

代码：

FastClr:
        ld      de,$555555      ; will write byte 85 (= blue color)
        or      a
        sbc     hl,hl
        ld      b,217
        di
        add     hl,sp           ; saves SP in HL
        ld      sp,vram+76818   ; for best optimisation , we'll write 18 extra bytes
ClrLp:  .fill 118,$d5           ;       = 118 * "PUSH DE"
        djnz    ClrLp           ; during 217 times
        ld      sp,hl           ; restore SP
        ei

16+4+8+8+4+4+16+217*(118*10+13)-5+4+4=258944 个状态！！！ ;D（ 经典的 LDIR 大约需要 537600 个状态）

Cemetech source 那里有更多（据称更快）示例。

这至少引起了对 LDIR 是最快选择的说法的某些怀疑，所以我会对@DrDnar 的 cmets 感兴趣。

注意：我并不是说该声明是错误的，因为我无法测试其中的任何内容并亲自查看。我注意到上述代码的作者虽然在原帖中提到了“TI83PCE/TI84+CE”，但仅在 TI83PCE 上执行实际测量 - 这可能很重要。

此外，代码中使用的地址和大小与 OP 的代码中的不同，并且提到了“8bpp 模式”，这再次告诉我很少，但 OP 没有提到任何特定的模式。

更新 4：@iPhoenix 提供的链接包含有关 TI-84+CE 的大量信息，包括 LCD Controller details。 本页解释了为什么上面代码的作者特别提到了“8bpp 模式”：

当 LCD 处于 8bpp 模式时，写入 VRAM 的数据将充当 8 位索引 到 LCD 的 256x16 位调色板。注意调色板 必须在设置此模式之前进行初始化，否则您将收到 意想不到的结果。 （有关信息，请参见 LCDPalette 寄存器 - 0x200 在调色板上）。这将有效地将 VRAM 的数量减半 存储全分辨率 320x240 图像（76800 字节 vs 153600 字节）。额外的 76800 字节 VRAM 可用于翻倍 缓冲区或用于临时数据存储。请注意，TIOS 不会 可在此模式下使用，它始终期望 16bpp 5:6:5 模式。

换句话说 - 不是用 0x31,0x00（大概是 16bpp 颜色）填充 153600 字节的 VRAM，OP 可以用单字节值 XY 填充 一半 的 VRAM 并配置（在实际填充之前）调色板，以便 XY 值映射到所需的 16bpp 颜色，从而获得相同的结果。

通过这种方法，任何在 31 和 00 之间交替的“不便”都会自然而然地消失。

Answer 3

tum_ 答案的变化与快于常规-dec bc 循环的零测试机制。

    LD   SP,$D65800    ; <end of VRAM>: 0xD40000+0x25800
    LD   BC,$004B      ; 0x4B many times (in C) the 256x inner loop (B=0)
        ; that results into 0x4B00 repeats of loop, which when 8 bytes per loop
        ; are set makes the total 0x25800 bytes (VRAM size)
        ; (if you would unroll it for more than 8 bytes, it will be a bit more
        ; tricky to calculate the initial BC to get correct amount of looping)
        ; (not that much tricky, just a tiny bit)
    LD   HL,31         ; H <- 0, L <- 31
.L1
    PUSH HL            ; (SP – 2) <- L, (SP – 1) <- H, SP <- SP - 2
    PUSH HL            ; set 8 bytes in each iteration
    PUSH HL
    PUSH HL
    DJNZ .L1           ; loop by B value (in this example it starts as 0 => 256x loop)
    DEC  C             ; loop by C ("outer" counter)
    JR   NZ,.L1        ; btw JP is faster than JR on original Z80, but not on eZ80
.END

（顺便说一句，我从来没有做过 eZ80 编程，我也没有在调试器中验证这一点，所以这有点假设......实际上正在考虑它，push 不是在 eZ80 32 位上吗？初始化的hl 应该是ld hl,$001F001F 设置四个字节与单个push，循环的内部应该只有两个push hl)

（但我做了 ton 的 Z80 编程，所以这就是为什么我什至费心评论这个话题，即使我以前从未见过 eZ80 代码）

编辑：原来 eZ80 推送是 24 位的，即上面的代码会产生不正确的结果。它当然可以很容易地修复（因为问题是实现细节，而不是主体），例如：

    LD   SP,$D65800    ; <end of VRAM>: 0xD40000+0x25800
    LD   BC,$0014      ; 0x14 many times (in C) the 256x inner loop (B=0)
        ; that results into 0x1400 repeats of loop, which with 30 bytes per
        ; loop set makes the total 0x25800 bytes (VRAM size)
    LD   HL,$1F001F    ; will set bytes 31,  0, 31
    LD   DE,$001F00    ; will set bytes  0, 31,  0
.L1
    PUSH DE
    PUSH HL
        ; here SP = SP-6, and 6 bytes 31, 0, 31, 0, 31, 0 were set
    PUSH DE
    PUSH HL
    PUSH DE
    PUSH HL
    PUSH DE
    PUSH HL
    PUSH DE
    PUSH HL            ; unrolled 5 times to set 30 bytes in total
    DJNZ .L1           ; loop by B value (in this example it starts as 0 => 256x loop)
    DEC  C             ; loop by C ("outer" counter)
    JR   NZ,.L1

Answer 4

首先，如果你要移动SP，你需要保存并恢复它。其次，您需要禁用中断，否则您将遇到竞争条件错误：如果在副本末尾附近触发中断，堆栈将向下增长到它下面的任何内容，这恰好是 VAT。

; Index registers are actually fast on the eZ80
    ld   ix, 0
    add  ix, sp
    di
; Do some hack using SP here
    ld   sp, ix
    ei

@Ped7g eZ80 会缓存任何-IR/-DR 后缀指令；与 Z80 不同，它不会在每次迭代时从内存中重新读取操作码。因此，像 LDIR 这样的指令可以在 2 个总线周期（一次读取和一次写入）内执行每次迭代。 因此，SP hack 不仅不必要地复杂，而且实际上速度更慢。 SP hack 最好还是留给更有经验的程序员。

eZ80 的流水线非常好，其性能受限于缺少任何缓存和 1 字节宽的总线。唯一比总线运行慢的指令是 MLT，这是一条需要 5 个时钟周期的 2 总线周期指令。对于每一条其他指令，只需计算操作码中的字节数，以及读写周期数，就可以知道它的执行时间。非常遗憾的是，在 TI-84+CE 系列中，TI 决定将快速 eZ80 与 SRAM 配对，该 SRAM 每次读写都需要 四个 时钟周期（48 MHz）！是的，半导体设计领域的世界领先者 TI 成功地设计了一个慢 SRAM。让片上 SRAM表现不佳是一项工程壮举。

@harold 有正确的答案，尽管我更喜欢优化大小而不是内部循环之外的速度。

#include "includes\ti84pce.inc"

    .assume ADL=1
    .org userMem-2
    .db tExtTok,tAsm84CeCmp

    call  _homeup
    call  _ClrScrnFull
; Initialize registers
    ld    hl, vRam
    ld    bc, lcdWidth * lcdHeight * 2 - 2
    push  hl
    pop   de
; Write initial 2-byte value
    ld    (hl), 31
    inc   hl
    ld    (hl), 0
    inc   hl
    ex    de, hl
; Copy everything all at once.  Interrupts may trigger while this instruction is processing.
    ldir
    call  _GetKey
    call  _ClrScrnFull
    ret

在 EFnet 上，#ez80-dev 是提问的好地方。 cemetech.net也是个好地方。