为什么复合组件无法父控件？

Question

我创建了自己的组件： TPage ，其中包含子组件 TPaper (TPanel)。 问题是，当我将 TMemo 或 TButton 等控件放在 TPaper 上（几乎填满整个区域）时，这些控件根本不会加载。见下面的例子

TPaper = class(TPanel)
  protected
      constructor Create(AOwner: TComponent);override;
      destructor Destroy;override;
  public
      procedure Paint; override;
  end;





TPage = class(TCustomControl)
   private
      FPaper:TPaper;
   protected
      procedure CreateParams(var Params:TCreateParams); override;
   public
      constructor Create(AOwner: TComponent);override;
      destructor Destroy;override;

   published
      property Paper: TPaper read FPaper write FPaper;
   end;




constructor TPage.Create(AOwner: TComponent);
  begin
  inherited Create(AOwner);

  PaperOrientation:=poPortrait;
  PaperSize:=psA4;
  PaperBrush:=TBrush.Create;
  PaperBrush.Color:=clWhite;
  PDFDocument:=Nil;
  FPaper:=TPaper.Create(Self);
  FPaper.Parent:=Self;
  FPaper.SetSubComponent(True);
  end;

... Memo1 在设计时是 TPaper (TPanel) 的父级，但在 按“运行”它不存在。

procedure TForm1.btn1Click(Sender: TObject);
begin
if not Assigned(Memo1) then ShowMessage('I do not exist');   //Memo1 is nil
end;

你知道出了什么问题吗？

非常感谢

PS 德尔福 7

当我将 TMemo 放入 TPaper 并保存单元 (Unit1) 后，在检查关联的 dfm 文件后，没有 TMemo 组件的痕迹。 （这就是它无法加载到应用程序的原因。）

Answer 1

Serge 是对的。 Delphi 只流式传输它们所在的表单所拥有的组件。为了避免在读取表单文件期间发生的 EClassNotfound 异常（您现在至少应该在 dfm 文件中看到一个 Tpaper 组件），您必须注册该类通过使用 RegisterClass 函数（在单元类中）。一个很好的地方是在你的单元的初始化部分。

如果无法将 Tpaper 的所有者设置为 Form，那么您仍然可以通过覆盖 Getchildren 和 GetChildOwner 方法并应用 TCustomForm 使用的逻辑来让 Delphi 流式传输您的子组件：

TPage = class
 ...
public
  procedure GetChildren(Proc: TGetChildProc; Root: TComponent); override;
  function GetChildOwner:TComponent; override;
end;



procedure TPage.GetChildren(Proc: TGetChildProc; Root: TComponent);  // this is copied
var                                                                  // from 
  I: Integer;                                                        // TCustomForm
  OwnedComponent: TComponent;
begin
  inherited GetChildren(Proc, Root);
  if Root = Self then
    for I := 0 to ComponentCount - 1 do
    begin
      OwnedComponent := Components[I];
      if not OwnedComponent.HasParent then Proc(OwnedComponent);
    end;
end;

function TPage.GetChildOwner: TComponent;
begin
  inherited;
  Result:=Self;
end;

Answer 2

这个问题是 5 年前的问题，但是因为我遇到了同样的问题并且在网络中找不到可行的解决方案，所以决定分享我在经过多次测试后找到的解决方案。

TClientPanel = class(TCustomControl)
private
  procedure WMNCHitTest(var Message: TWMNCHitTest); message WM_NCHITTEST;
public
  constructor Create(AOwner: TComponent); override;
end;

TMainPanel = class(TCustomControl)
private
  FClient: TClientPanel;
protected
  function GetChildOwner: TComponent; override;
  procedure GetChildren(Proc: TGetChildProc; Root: TComponent); override;
  procedure ReadState(Reader: TReader); override;
  procedure CreateComponentEvent(Reader: TReader; ComponentClass: TComponentClass; var Component: TComponent);
public
  constructor Create(AOwner: TComponent); override;
  destructor Destroy; override;
...
end;

constructor TClientPanel.Create(AOwner: TComponent);
begin
  inherited Create(AOwner);
  ControlStyle := ControlStyle + [csAcceptsControls, csNoDesignVisible];
end;

procedure TClientPanel.WMNCHitTest(var Message: TWMNCHitTest);
begin
  if not (csDesigning in ComponentState) then
    Message.Result := HTTRANSPARENT
  else
    inherited;
end;

var
  TClientPanel_Registered: Boolean = False;

constructor TMainPanel.Create(AOwner: TComponent);
begin
  inherited Create(AOwner);
  FClient := TClientPanel.Create(Self);
  FClient.Parent := Self;
  FClient.Align := alClient;
  Exclude(FComponentStyle, csInheritable);
  if not TClientPanel_Registered then
  begin
    RegisterClasses([TClientPanel]);
    TClientPanel_Registered := True;
  end;
end;

destructor TMainPanel.Destroy;
begin
  FClient.Free;
  inherited Destroy;
end;

function TMainPanel.GetChildOwner: TComponent;
begin
  Result := Self;
end;

procedure TMainPanel.GetChildren(Proc: TGetChildProc; Root: TComponent);
begin
  Proc(TControl(FClient));
end;

procedure TMainPanel.CreateComponentEvent(Reader: TReader; ComponentClass: TComponentClass; var Component: TComponent);
begin
  if ComponentClass.ClassName = 'TClientPanel' then Component := FClient;
end;

procedure TMainPanel.ReadState(Reader: TReader);
begin
  Reader.OnCreateComponent := CreateComponentEvent;
  inherited ReadState(Reader);
  Reader.OnCreateComponent := nil;
end;

不是很专业，但我希望它会有所帮助:^)

附：刚刚做了一个快速测试（XE5），但基本上可以工作。