Delphi隐藏表单，不隐藏任务栏上的应用程序图标

Question

我使用以下代码：

procedure TForm1.Button1Click(Sender: TObject);
begin
  Form1.visible := false;
  Form2.show;
end;

是的，form1 被隐藏了，而 form2 出现了。但是为什么任务栏中的应用程序图标也被隐藏了......

我使用以下代码，仍然无法在任务栏上显示图标，同时隐藏了form1。

      visible := false;
{
      enable := false;
      Application.MainFormOnTaskbar := True;
      ShowWindow(Application.Handle, SW_SHOW);
      SetWindowLong(Application.Handle, GWL_EXSTYLE, GetWindowLong(Application.Handle, GWL_EXSTYLE) or WS_EX_TOOLWINDOW);
}

当我想隐藏表单时，如何将应用程序图标保留在任务栏上？

我想在单元文件中进行，而不是在 DPR 文件中。

我想要保留系统任务栏的文件位于：http://sidhiciang.com/myfiles/ShowHideForms.rar

Unit1.pas
  If Form1.btShowForm2Click() , then 
    Hide Form1 and Show Form2 ( actHideForm1execute(self)).
  If Form1.btCloseForm1Click(), then 
    Close the application

Unit2.pas
  If  Form2.btShowForm3Click(), then 
    Hide Form2 and Show Form3 ( actHideForm2execute(self)).
  If Form2.btCloseForm2Click(), then 
    Show the Form1 and Form2.close (actShowForm1execute(self))

Unit3.pas
  If btCloseFrom3Click(), then
    Show Form2 and Close Form3

在所有的 Unit1 / Unit2 / Unit3 中，保持任务栏上的应用程序图标可用。因为如果我使用 .visible := false，系统任务栏也会被隐藏。

PS：我使用 Delphi 2010 并在 Windows XP 和 7 环境上运行。

Answer 1

您可以在任务栏上显示的句柄之间切换。
隐藏时显示应用程序，显示时显示表单。

procedure TForm1.HideIt;
begin
  Visible := false;
  Application.MainFormOnTaskbar := false;
  ShowWindow(Application.Handle, SW_SHOW);
end;

procedure TForm1.ShowIt;
begin
  Visible := true;
  Application.MainFormOnTaskbar := true;
  ShowWindow(Application.Handle, SW_Hide);
end;

// overrride CreateParams:  procedure CreateParams(var Params: TCreateParams); override;
procedure TForm1.CreateParams(var Params: TCreateParams);
begin
  inherited;
  Params.ExStyle := Params.ExStyle or WS_EX_APPWINDOW;
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  Application.MainFormOnTaskbar := true;
end;

Answer 2

假设Form1 是主窗体，Form1.Hide 做你想做的一切，除了任务栏按钮应该保持可见，那么你真正想做的就是最小化应用程序：

Application.Minimize;

---

否则，您可能正在寻找Hide the Main Form。

Answer 3

好的，既然你想要什么已经很清楚了，首先要做两件事：

• 创建的第一个表单自动成为 MainForm，
• 应用程序不能没有 MainForm；当 MainForm 关闭时，应用程序将关闭，无论显示什么其他表单，
• 您可以隐藏 MainForm，
• 默认情况下（无论如何在旧版本的 Delphi 中）应用程序的窗口显示在任务栏上 (Application.MainFormOnTaskbar = False)。只要应用程序处于活动状态，并且至少显示一个表单，此图标/窗口就会显示在任务栏中。
• Application.MainFormOnTaskbar = True 时，主窗体的图标/窗口显示在任务栏中。当 MainForm 被隐藏时，图标消失。显示另一个表单不会导致另一个任务栏图标/窗口，因此根本没有图标。

所以，很明显你需要在项目文件中设置Application.MainFormOnTaskbar := False。

此外，以下方法组合似乎可以按您的意愿工作：

Unit1/Form1/MainForm：

procedure TForm1.CloseButtonClick(Sender: TObject);
begin
  Close;
end;

procedure TForm1.OpenForm2ButtonClick(Sender: TObject);
begin
  TForm2.Create(Self).Show;
  Hide;
end;

Unit2/Form2：

procedure TForm2.CloseButtonClick(Sender: TObject);
begin
  Close;
end;

procedure TForm2.FormClose(Sender: TObject; var Action: TCloseAction);
begin
  TForm(Owner).Show;
  Action := caFree;
end;

procedure TForm2.OpenForm3ButtonClick(Sender: TObject);
begin
  TForm3.Create(Self).Show;
  Hide;
end;

Unit3/Form3：

procedure TForm3.CloseButtonClick(Sender: TObject);
begin
  Close;
end;

procedure TForm3.FormClose(Sender: TObject; var Action: TCloseAction);
begin
  TForm(Owner).Show;
  Action := caFree;
end;

请注意，任务栏按钮的标题在这些更改期间保持不变。如果您想将其与显示的表单标题同步，请设置Application.Title。