记忆和类型类

Question

为了简单起见，我将使用这个人为的示例类（关键是我们有一些从方法派生的昂贵数据）：

class HasNumber a where
  getNumber :: a -> Integer
  getFactors :: a -> [Integer]
  getFactors a = factor . getNumber

当然，我们可以做这个类的memoizing实现，比如：

data Foo = Foo {
  fooName :: String,
  fooNumber :: Integer,
  fooFactors :: [Integer]
}

foo :: String -> Integer -> Foo
foo a n = Foo a n (factor n) 

instance HasNumber Foo where
    getNumber = fooNumber
    getFactors = fooFactors

但要求手动将“因素”字段添加到任何将成为HasNumber 实例的记录似乎有点难看。下一个想法：

data WithFactorMemo a = WithFactorMemo {
    unWfm :: a,
    wfmFactors :: [Integer]
}

withFactorMemo :: HasNumber a => a -> WithFactorMemo a
withFactorMemo a = WithFactorMemo a (getFactors a)

instance HasNumber a => HasNumber (WithFactorMemo a) where
    getNumber = getNumber . unWfm
    getFactors = wfmFactors

不过，这将需要大量样板来将原始 a 的所有其他操作提升到 WithFactorMemo a。

有什么优雅的解决方案吗？

Answer 1

解决方案如下：丢失类型类。我已经讨论过这个here 和here。任何类型类TC a，其每个成员都将单个a 作为参数，与数据类型同构。这意味着HasNumber 类的每个实例都可以用这种数据类型表示：

data Number = Number {
    getNumber' :: Integer,
    getFactors' :: [Integer]
}

即通过这种变换：

toNumber :: (HasNumber a) => a -> Number
toNumber x = Number (getNumber x) (getFactors x)

Number 显然也是HasNumber 的一个实例。

instance HasNumber Number where
    getNumber = getNumber'
    getFactors = getFactors'

这个同构告诉我们这个类是变相的数据类型，它应该死掉。只需使用 Number 代替。最初如何做到这一点可能并不明显，但有了一点经验应该很快就会到来。例如，您的 Foo 类型变为：

data Foo = Foo {
    fooName :: String,
    fooNumber :: Number
}

您的记忆将免费提供，因为这些因素存储在 Number 数据结构中。