Writer monad 中的记忆

Question

注意 我只是想了解下面显示的这段特定代码中发生了什么。我知道这可能不是解决问题的最佳方法。

我正在尝试将惰性 Writer monad 与 memozied fibonacci 函数一起使用来计算函数被调用的次数。该函数快速返回正确的值，但Writer 环境永远不会返回并且不使用任何 CPU 或内存。

import Control.Monad.Writer.Lazy as W

fib :: Int -> Writer (Sum Int) Int
fib = let fibs = mapM fib' [0..]
          fib' 0 = return 0
          fib' 1 = return 1
          fib' n = liftM2 (+) (fib $ n-1) (fib $ n-2)
      in \n -> tell (Sum 1) >> fibs >>= return . (!!n)

Prelude W> runWriter $ fib 51
(20365011074,Sum {getSum = Interrupted.

有人可以解释发生了什么吗？为什么环境不返回值？

编辑

无限列表[0..] 不是这里的问题。我尝试用有限的列表替换它，例如[0..10] 或[0..n]，但问题仍然存在。 如果无限列表是问题所在，那将是一个非常消耗内存的计算，这就是为什么我在上面提到它不消耗任何 CPU 或内存，这让我感到困惑。

我相信，由于懒惰，在评估 fib 函数的节点时，某处会出现死锁。

Answer 1

问题是mapM fib' [0..]。这是一个计算 monad 中无限列表的有效计算，为此它还需要组合无限数量的效果，在本例中为 tell (Sum 1)。感谢Writer 的懒惰，您可以访问结果，但幺半群部分内的计数永远不会结束。

更新：即使您将列表设为有限，它仍然无法正常工作。问题是mapM fib' [0..10] 表示“斐波那契数列和计算它们所需的调用总数”。因此，在您的表达式 tell (Sum1) >> fibs >>= ... 中，您总是将 所有调用的总数 添加到计数器中，这显然是您不想要的。

此外，它创建了一个无限循环：对fib 的任何调用都会调用fib'，它计算对其所有元素的调用次数，因此调用（以及其他调用）fib' 2，它再次调用fib .仅当您将列表限制为 [0..1] 时，无限递归才会停止。同样，问题在于mapM 结合了给定一元计算的所有效果。

相反，你需要这样的东西：

import Control.Monad.Writer.Lazy as W

fib :: Int -> Writer (Sum Int) Int
fib = let fibs = map fib' [0..] -- <<<<
          fib' 0 = return 0
          fib' 1 = return 1
          fib' n = liftM2 (+) (fib $ n-1) (fib $ n-2)
      in \n -> tell (Sum 1) >> fibs !! n -- <<<<

这里是fibs :: [Writer (Sum Int) Int]，因此对于每个元素，它都包含结果和计算所需的调用次数。