如何在标签单击上选择文本框

Question

在 Microsoft Access 中，当您单击标签时，与该标签关联的文本框将获得焦点。据我所知，VB.NET 没有同样的功能。我知道我总是可以在标签的点击事件中添加一些东西，就像这样......

TextBox1.Focus()

但是我在表单上有几十个字段，如果我不需要将它添加到每个标签的点击事件中，它会变得容易得多。

我想有可能为所有标签创建一个事件，强制一个选项卡到下一个控件，并假设我正确设置了选项卡索引，那么这将起作用。向表单添加新字段时会出现问题，在这种情况下，所有选项卡索引都需要重新验证。

Private Sub Label1_Click(sender As Object, e As EventArgs) Handles Label1.Click, Label2.Click
    'code to tab to next field...
End Sub

有没有更简单的方法？

Answer 1

如何创建一个字典，其中标签是键，焦点控件是值，然后将 Click 事件处理程序添加到字典中的所有标签。每次添加标签/控件时，您需要做的就是在字典中添加另一个 KeyValuePair

简单示例：

 Public Class Form1
    Protected Friend DicLabelToControl As Dictionary(Of Label, Control)

    Protected Friend Sub InitLabelDic()
        DicLabelToControl = New Dictionary(Of Label, Control) From {{Label1, TextBox1}, {Label2, TextBox2}}
    End Sub

    Protected Friend Sub AddClickEventsToLabels()
        For Each lb As Label In DicLabelToControl.Keys
            AddHandler lb.Click, AddressOf HandleLabelClick
        Next
    End Sub

    Private Sub HandleLabelClick(sender As Object, e As EventArgs)
        DicLabelToControl(CType(sender, Label)).Focus()

    End Sub



    Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
        InitLabelDic()
        AddClickEventsToLabels()
    End Sub
End Class

Answer 2

首先，在表单上设置控件的 TabIndex 顺序，然后使用以下代码：

Public Class Form1

    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        For Each c As Control In Me.Controls
            If TypeOf c Is Label Then AddHandler c.Click, AddressOf Label_Click
        Next
    End Sub

    Private Sub Label_Click(ByVal sender As Object, ByVal e As System.EventArgs)
        Me.SelectNextControl(sender, True, True, True, True)
    End Sub
End Class

现在，每当您单击标签时，顺序中的以下控件都会被聚焦。