Excel VBA/按钮同时刷新两个或多个枢轴

Question

在另一篇文章中，我获得了以下 VBA 代码，用于附加到“刷新”按钮以刷新 Pivot 数据：

Option Explicit

Sub Button5_Click()

Dim PvtTbl                  As PivotTable
Dim PvtCache                As PivotCache
Dim PvtDataRng              As Range

' Set/Update Pivot Data Range
Set PvtDataRng = Worksheets("PivotDataSheet").Range("A1:E100") ' <-- just an example

' Create/Update Pivot Cache
Set PvtCache = ActiveWorkbook.PivotCaches.Add(xlDatabase, PvtDataRng)

' Set the Pivot Table (already created, otherwise need to create it)
Set PvtTbl = Worksheets("DD").PivotTables("test")

' refresh the Pivot Table with the latest Pivot Cache
With PvtTbl
    .ChangePivotCache PvtCache
    .RefreshTable
End With

End Sub

如何修改此代码以同时刷新同一工作表中的第二个数据透视？让我们将此第二个枢轴称为“test2”，它也在 DD 工作表中。

谢谢， 凯夫博

Answer 1

如果您在“DD”工作表中只有这 2 个 PivotTable，并且您想根据相同的 PivotCache 更新这 2 个，则替换以下 For 循环：

With PvtTbl
    .ChangePivotCache PvtCache
    .RefreshTable
End With

使用以下For 循环：

' refresh all Pivot Tables in "DD" worksheet
For Each PvtTbl In Worksheets("DD").PivotTables
    With PvtTbl
        .ChangePivotCache PvtCache
        .RefreshTable
    End With
Next PvtTbl

---

编辑 1：Set PivotCache 在 For 循环内，并在最后清除它。使用下面的循环，并从之前的位置删除 Set PvtCache 行。

' refresh all Pivot Tables in "DD" worksheet
For Each PvtTbl In Worksheets("DD").PivotTables
    ' Create/Update Pivot Cache
    Set PvtCache = ActiveWorkbook.PivotCaches.Add(xlDatabase, PvtDataRng)

    With PvtTbl
        .ChangePivotCache PvtCache
        .RefreshTable
    End With

    Set PvtCache = Nothing ' <-- clear the Pivot Cache
Next PvtTbl

Answer 2

我自己没有对此进行测试，但您可以尝试告诉我它是否有效。看起来它可能对你有用

Function refreshPTcontent()

Dim ws As Worksheet
Dim pt As PivotTable
Dim pf As PivotField
Dim pi As PivotItem

On Error Resume Next
    For Each ws In ActiveWorkbook.Worksheets
       For Each pt In ws.PivotTables
         pt.RefreshTable
       Next pt
    Next ws

End Function