接口继承只不过是语法糖吗？

Question

下面的代码不起作用。

program Project7;    
{$APPTYPE CONSOLE}
{$R *.res}

uses System.SysUtils;

type
  I1 = interface
    ['{B4BF44AD-23A9-4F42-BA2B-6E137E22344E}']
    procedure Test1;
  end;

  I2 = interface(I1)
    ['{AAAAAAAA-23A9-4F42-BA2B-BBBBBBBBBBBB}']
    procedure Test2;
  end;

  T12 = class(TInterfacedObject, I2)
  public
    procedure Test1;
    procedure Test2;
  public
    function MeAsI1: I1;
    function MeASI2: I2;
  end;

function T12.MeAsI1: I1;
begin
  Result:= (self as I1);
end;

function T12.MeASI2: I2;
begin
  Result:= (self as I2);
end;

procedure T12.Test1;
begin
 Writeln('T12: test1 from interface i1');
end;

procedure T12.Test2;
begin
   Writeln('T12: test2 from interface i2');
end;

实施：

var
  MyClass: T12;
  AI1: I1;
  AI2: I2;
begin
  MyClass:= T12.Create;
  AI2:= MyClass.MeAsI2;
  AI2.Test2;
  Readln;
  AI1:= MyClass.MeAsI1;    //<< Exception interface not supported
  AI1.Test1;
  Readln;
end.

它给出了一个例外：interface not supported。
看起来 interface inheritance 不像 class inheritance 那样工作。
如果我将接口 I1 添加到类 T12 中，它确实可以工作，但是当一个类实现许多接口时，这会变得有点傻。
有没有办法只声明 I2 并且仍然能够从类内部返回对 I1 的引用？
我使用的是Delphi XE6，但我确定Delphi 3中的错误是一样的。

编辑
一个用例是：

 IReadOnly = interface
   function GetSomething: integer;
   ...

 IRWIntf = interface(IReadOnly)
   procedure SetSomething(value: integer);
   ....

Answer 1

这是设计使然。您只能从类声明中明确提及的类中检索那些接口。

关于您的示例：由于 I2 是从 I1 继承的，因此您可以直接从 AI2 调用 I1 的方法，也可以在需要 I1 接口的任何地方传递 AI2。

Answer 2

接口继承遵循接口的逻辑。使用接口，您可以在没有任何实现的情况下定义声明。所以继承的接口有相同的声明，仅此而已，因此不会有实现继承。

但您可以执行以下操作

procedure UseI1( AI1 : I1 );
begin
  AI1.Test1;
end;

procedure UseI2( AI2 : I2 );
begin
  AI2.Test1;
  AI2.Test2;
  UseI1( AI2 ); // use the inherited interface
end;

如果您希望示例类输出I1，那么您必须更改方法

function T12.MeAsI1: I1;
var
  LI2 : I2;
begin
  LI2 := Self;
  Result := LI2;
end;

---

但你必须小心。考虑一个实现I1 和I2 的类

TImplementor = class( TInterfacedPersistent, I1, I2 )
private
  procedure I1_Test1;
  procedure I2_Test1;
  procedure I2_Test2;

  procedure I1.Test1 = I1_Test1;
  procedure I2.Test1 = I2_Test1;
  procedure I2.Test2 = I2_Test2;
end;

procedure TImplementor.I1_Test1;
begin
  Writeln( 'I1_Test1' );
end;

procedure TImplementor.I2_Test1;
begin
  Writeln( 'I2_Test1' );
end;

procedure TImplementor.I2_Test2;
begin
  Writeln( 'I2_Test2' );
end;

现在我们可以使用它了

var
  LImplementor : TImplementor;
begin
  LImplementor := TImplementor.Create;
  try
    UseI1( LImplementor );
    // Output
    // I1_Test1
    UseI2( LImplementor );
    // Output
    // I2_Test1
    // I2_Test2
    // I2_Test1 !!!!!
  finally
    LImplementor.Free;
  end;
end;

虽然我们调用了两次UseI1，但我们得到了两个不同的输出，因为调用了两个不同的方法。