使用存储在二维数组中的相关数据

Question

我正在努力理解数组并围绕该主题进行阅读，但是当您刚刚开始编程并且没有人可以要求解释时，很多文献并不容易理解。这是我的二维数组：

        'Declare 2-diensional array of Strings
    Dim cars(,) As String =
    New String(,) {{"BMW", "Coupe", "Reg:2015", "5 Door"},
           {"Ford", "Focus", "Reg:2015", "3 Door"},
           {"Land Rover", "Discovery", "Reg:2014", "5 Door"},
           {"Vauxhall", "Astra", "Reg:2014", "3 Door"},
           {"SEAT", "Ibiza", "Reg:2013", "5 Door"}}

    ' Get bounds of the array.
    Dim bound0 As Integer = cars.GetUpperBound(0)
    Dim bound1 As Integer = cars.GetUpperBound(1)

    ' Loop over all elements.
    For i As Integer = 0 To bound0
        For x As Integer = 0 To bound1
            ' Get element.
            Dim s1 As String = cars(i, x)
            Console.ForegroundColor = ConsoleColor.Green
            Console.Write(s1 & ", ")
        Next
        Console.WriteLine()
    Next
    Console.ReadKey()
    Console.WriteLine("Please enter the name of the record you wish to view")
    Dim s = Console.ReadLine()
    Dim value As String = Array.Find(cars, Function(x) (x.StartsWith(s)))
    Console.WriteLine(value)
    Console.ReadKey()

这是导致问题的行

Dim value As String = Array.Find(cars, Function(x) (x.StartsWith(s)))

Visual Studio 提示该错误是因为“无法从这些参数推断类型参数的数据类型。明确指定数据类型可能会更正此错误。” 我无法理解这个错误的含义。请有人可以解释一下，就像在和一个 10 岁的孩子说话一样，或者也许是一个可以帮助我理解这个问题的网站。谢谢

Answer 1

关键在于数据是相关的。与其将您的“汽车”分解成碎片以存储在不同的数组中，一个类将允许您创建一个Car 对象，并将各种汽车存储在一个类型化的List 中：

五分钟介绍Classes 和Lists

Public Class Car
    Public Property Id As Int32
    Public Property Make As String
    Public Property Model As String
    Public Property Year As Int32
    '... etc
End Class

现在您有了一个容器来保存一辆车的所有信息。这就像Car 对象的外观蓝图。类还可以包含方法（Sub 或 Function）来管理它们存储的数据，以便与汽车、员工或订单相关的所有内容都可以由该类管理。

Dim c As New Car          ' create a new car object
c.Make = "Mazda"
c.Model = "Miata"
c.Year = 2013

或者在声明的时候初始化：

Dim c As New Car With {.Make = "Mazda", .Model = "Miata" ...}

现在，新千年版本的数组是List。它们更容易使用，因为它们会自行调整大小：

Dim Cars As New List(Of Car)

Cars 集合只能存储汽车对象，它存储的每辆汽车都将数据保存在一起。还有许多其他集合类型，例如Dictionary，您最终会想要熟悉。将马自达添加到列表中：

' c is the car object created above
Cars.Add(c)

与数组不同，您无需知道您将使用多少辆汽车，因为它们会自行调整大小。要引用一个，Cars(n) 将引用汽车对象：

' n is the index of a car in the list
Dim str = Cars(n).Make & " is " & Cars(n).Color

使用 temp Car 变量迭代列表：

For Each c As Car In Cars   
    ' c will be Cars(0), Cars(1) etc as we step thru
    Console.WriteLine("Index {0} is a BEAUTIFUL {1} {2}",
           Cars.IndexOf(c), c.Year, c.Model)
    ' e.g
    ' "Index 4 is a BEAUTIFUL 2015 Camry"
Next

找到一个或第一个：

Dim myCar = Cars.FirstOrDefault(Function (f) f.Make = "Mazda" AndAlso f.Year = 2013)

List(Of T) 可以用作某些控件的DataSource：

myDGV.DataSource = Cars

DataGridView 将为Car 类中的每个Property 创建一个列，并为列表中的每个汽车对象添加一行 - 很简单！

或者：

myListBox.DataSource
myList.DisplayMember = "Make"
myList.ValueMember = "Id"

用户将在 ListBox（或您定义的任何内容）中看到 Make。 SelectedValue 将是他们选择的汽车对象的 ID，SelectedItem 将是整个汽车对象。无需遍历不同的数组来查找相关数据 - 它始终在一个位置。