从字典返回类属性数组

Question

_背景：

在最近尝试回答 question 时，我自己在想是否可以直接从字典项返回一个类对象属性数组。

_代码：

把TstClass想象成一个类模块，代码如下：

Public val1 As Variant
Public val2 As Variant
Public val3 As Variant

然后这段代码来测试：

Sub Test()

Dim dict As Object: Set dict = CreateObject("Scripting.Dictionary")
Dim lst As TstClass, key As Variant, arr As Variant

For x = 1 To 3
    Set lst = New TstClass
    lst.val1 = "A" & x
    lst.val2 = "B" & x
    lst.val3 = "C" & x
    dict.Add x, lst
Next x

For Each key In dict
    arr = Array(dict(key).val1, dict(key).val2, dict(key).val3)
Next key

End Sub

_问题：

在上述情况下，Array(dict(key).val1, dict(key).val2, dict(key).val3) 将返回数组就好了，但如果我们想象val4-val50 它将变成更多的代码。使用Array(...) 或逐行写出Debug.Print Dict(key).Valx。

_问题：

是否可以直接从字典键的类对象属性中返回一个数组？对我来说最明显的尝试是arr = Dict(key)，希望它能以某种方式识别我需要该项目的所有属性。除此之外，不允许将常量、数组、用户定义类型声明为 Public，所以像 Public Vals(0 to 2) 这样的东西也不起作用。

谢谢你， 合资公司

Answer 1

从@RyanWildry 的答案中获得灵感，我发现尽管无法使用Public 变体数组，但我们可以使用Private 变体数组。因此，我使Property Let 将值分配给数组中的特定索引。

创建一个Public Function 以返回Private 数组变量将一次性返回该数组。

---

_{类模块，名为TstClass}

Private vals(0 To 2) As Variant

Public Property Let val(ByVal x As Long, ByVal NewVal As Variant)
    vals(x) = NewVal
End Property

Public Function GetArray() As Variant
    GetArray = vals
End Function

_{Module1 下的代码}

Sub Test()

Dim dict As Object: Set dict = CreateObject("Scripting.Dictionary")
Dim lst As TstClass, key As Variant, arr As Variant

For x = 1 To 3
    Set lst = New TstClass
    lst.val(0) = "A" & x
    lst.val(1) = "B" & x
    lst.val(2) = "C" & x
    dict.Add x, lst
Next x

For Each key In dict
    arr = dict(key).GetArray
Next key

End Sub

---

另一种方法是不考虑 Class 模块的想法，而使用（例如）ArrayList 对象：

Sub Test()

Dim dict As Object: Set dict = CreateObject("Scripting.Dictionary")
Dim lst As Object: Set lst = CreateObject("System.Collections.ArrayList")
Dim arr As Variant

For x = 1 To 3
    lst.Add "A" & x
    lst.Add "B" & x
    lst.Add "C" & x
    dict.Add x, lst.Toarray
    lst.Clear
Next x

For Each key In dict
    arr = dict(key)
Next key

End Sub

但是，后一种方法会超出这个问题的目的。

这与直接从字典项返回数组一样接近。我很高兴收到建设性的反馈或其他/更好的方式，因为 Class 模块对我来说相当新，这仍然不能回答关于如何直接返回属性数组的问题的本质。

Answer 2

不确定这是否正是您所追求的，但是可以在您的类中创建一个方法来构建您想要的属性数组。然后，您可以在该类的每个实例上调用它以获取数组详细信息。

类 - 命名为“示例”：

Public val1 As Variant
Public val2 As Variant
Public val3 As Variant

Public Function GetArray() As Variant
    GetArray = Array(Me.val1, Me.val2, Me.val3)
End Function

客户端代码 - 在标准模块中：

Sub SOExample()

    Dim dict As Object: Set dict = CreateObject("Scripting.Dictionary")
    Dim lst As Example, arr As Variant, key As Variant

    For x = 1 To 3
        Set lst = New Example
        lst.val1 = "A" & x
        lst.val2 = "B" & x
        lst.val3 = "C" & x
        dict.Add x, lst
    Next

    For Each key In dict.keys
        arr = dict(key).GetArray
        Debug.Print Join(arr, ",")
    Next

End Sub

输出：

A1,B1,C1
A2,B2,C2
A3,B3,C3