如何获得上周日的日期？答案

【问题标题】：How to get last Sunday's date?如何获得上周日的日期？
【发布时间】：2020-03-19 03:51:07
【问题描述】：

我需要在单元格中显示上周日的日期，以便在 Google 表格上创建每周报告。我一直在谷歌上寻找解决方案，我找到的最接近的是：

=TODAY()+(7-WEEKDAY(TODAY(),3))

但这给出了下周一的日期。知道如何修改它以显示上周日的日期吗？或者，您有其他方法来解决这个问题吗？

【问题讨论】：

如果更改数字会怎样？不要使用谷歌表格，这样会让你测试......

标签： date google-sheets google-sheets-formula array-formulas weekday

【解决方案1】：

使用星期一作为 1 索引，如果是星期天，这将返回上一个星期日或今天

=if((7-WEEKDAY(today(),2))>0,today()-(7-(7-WEEKDAY(today(),2))),today()+(7-WEEKDAY(today(),2)))

可以通过在模式存在的三个位置直接更改“-WEEKDAY(today(),2)”之前的数字“7”来选择一周中的其他日子。

【讨论】：

【解决方案2】：

尝试：

=ARRAYFORMULA(TO_DATE(FILTER(ROW(INDIRECT(VALUE(TODAY()-6)&":"&VALUE(TODAY()))), 
 TEXT(ROW(INDIRECT(VALUE(TODAY()-6)&":"&VALUE(TODAY()))), "ddd")="Sun")))

如果今天是星期天，而您仍然想要最后一个星期日：

=ARRAYFORMULA(IF(TEXT(TODAY(), "ddd")="Sun", TODAY()-6, 
 TO_DATE(FILTER(ROW(INDIRECT(VALUE(TODAY()-6)&":"&VALUE(TODAY()))), 
 TEXT(ROW(INDIRECT(VALUE(TODAY()-6)&":"&VALUE(TODAY()))), "ddd")="Sun"))))

【讨论】：

【解决方案3】：

您要查找的公式是：

=DATE(YY, MM, DD) - (WEEKDAY(DATE(YY, MM, DD)) - 1) - 7

// OR

=TODAY() - (WEEKDAY(TODAY()) - 1) - 7

根据您对“上周日”的理解，您可以简化/考虑这一点：

如果您将“上周日”表示为，“最近发生的周日：”

=DATE(A2,B2,C2) - WEEKDAY(DATE(A2,B2,C2)) + 1

如果您将“上周日”表示为，“上一周发生的周日：”

=DATE(A4,B4,C4) - WEEKDAY(DATE(A4,B4,C4)) - 6

解决它：

=TODAY() - (WEEKDAY(TODAY()) - 1) - 7


 TODAY()
 // get today's date, ie. 22/11/2019

            WEEKDAY(TODAY())
            // get the current day of the week, ie. 6 (friday)

         -
         // take the first date and subtract that to rewind through the week,
         // ie. 16/11/2019 (last saturday, since saturday is 0)

                             - 1
                             // rewind back one less than the entire week
                             // ie. 17/11/2019 (this sunday)

                                  - 7
                                  // rewind back to the sunday before this
                                  // sunday, ie. 10/11/2019

希望这个解释能解释最后的数字在做什么。 + 1 带你从上周的星期六到本周的星期日（我称之为“这个星期天”），- 6 带你回到上周的我称之为“上星期天”。

请看这里：

【讨论】：