如何在 FMX 画布上用 Delphi 画一条线

Question

这是 Delphi Berlin 10.1 Update 2

以下作品（我画了一条线）：

brush := TStrokeBrush.Create(TBrushKind.Solid, TAlphaColors.Lightgray);
brush.Thickness := 2;
with Canvas do
begin
    BeginUpdate;
    DrawLine(PointF(10, 10), PointF(100, 10), 1, brush);
    EndUpdate;
end;

以下不起作用：

with Canvas do
begin
    BeginUpdate;
    Stroke.Color := TAlphaColors.Black;
    Stroke.Thickness := 2.0;
    DrawLine(PointF(10, 10), PointF(100, 10), 1);
    EndUpdate;
end;

为什么我不能使用第二个？我怎样才能让它工作，或者我应该像第一个例子一样坚持创建笔刷？

我已经包含了一个最小的应用程序：

main.pas

unit main;

interface

uses
    System.SysUtils, System.Types, System.UITypes, System.Classes, System.Variants,
FMX.Types, FMX.Controls, FMX.Forms, FMX.Graphics, FMX.Dialogs, FMX.Objects;

type
    TMainForm = class(TForm)
        PaintBox: TPaintBox;
        procedure OnPaint(Sender: TObject; Canvas: TCanvas);
    private
        { Private declarations }
    public
        { Public declarations }
    end;

var
    MainForm: TMainForm;

implementation

{$R *.fmx}

procedure TMainForm.OnPaint(Sender: TObject; Canvas: TCanvas);
begin
    with Canvas do
    begin
        BeginUpdate;
        Stroke.Color := TAlphaColors.Black;
        Stroke.Thickness := 2.0;
        DrawLine(PointF(10, 10), PointF(100, 10), 1);
        EndUpdate;
    end;
end;

end.

main.fmx:

object MainForm: TMainForm
    Left = 0
    Top = 0
    Caption = 'Form1'
    ClientHeight = 480
    ClientWidth = 640
    FormFactor.Width = 320
    FormFactor.Height = 480
    FormFactor.Devices = [Desktop]
    DesignerMasterStyle = 0
    object PaintBox: TPaintBox
        Position.X = 16.000000000000000000
        Position.Y = 16.000000000000000000
        Size.Width = 609.000000000000000000
        Size.Height = 449.000000000000000000
        Size.PlatformDefault = False
        OnPaint = OnPaint
    end
end

test.dpr：

program test;

uses
   System.StartUpCopy,
   FMX.Forms,
   main in 'main.pas' {MainForm};

{$R *.res}

begin
    Application.Initialize;
    Application.CreateForm(TMainForm, MainForm);
    Application.Run;
end.

Answer 1

早期版本的 Delphi 对 Stroke.Kind 有不同的默认值，具体取决于平台。

自 Delphi 10.1 Berlin 以来，所有平台的默认值似乎都是 None。 （感谢@TomBrunberg）

要使线条出现，请设置Stroke.Kind := TBrushKind.Solid;

注意：在 Windows 8.1 上测试

---

我还创建了一个新的 Metropolis FMX 应用程序，其中绘图工作没有设置 Stroke.Kind。虽然无法解释。

---

QP 提交了一份类似的报告，RSP-16313 The Canvas.DrawLine doesn't work at Windows XP (32 bit) forms。这里问题在 Windows-XP 上出现，但在 Windows-7 上没有。

Answer 2

第一种情况很奇怪。

你应该使用笔刷。

您应该使用 BeginScene 和 EndScene 而不是 BeginUpdate 和 EndUpdate。该片段完美运行：

  Brush := TStrokeBrush.Create(TBrushKind.Solid, TAlphaColors.Black);
  Brush.Thickness := 2;
  with Canvas do
  begin
    BeginScene();
    DrawLine(PointF(10, 10), PointF(100, 10), 1, Brush);
    EndScene;
  end;