在 ELM 中解码嵌套的可变长度 JSON

Question

我无法在 ELM 中解码一个有点复杂的 JSON 响应。 JSON 响应结构（我无法控制）与我的应用程序的数据树/模型不匹配。

这个 JSON 的解码器代码是什么样的？

我正在使用 NoRedInk 的 Json.Decode.Pipeline - http://package.elm-lang.org/packages/NoRedInk/elm-decode-pipeline/3.0.0/Json-Decode-Pipeline

我的项目的 Github 存储库 - https://github.com/areai51/my-india-elm

JSON 响应 - https://data.gov.in/node/85987/datastore/export/json

代码

 type alias Leader =
    { attendance : Float      <------- Logic = (Sessions Attended / Total Sessions) * 100
    , name : String
    , state : String
    }


type alias Model =
    { leaders : WebData (List Leader)
    }


initialModel : Model
initialModel =
    { leaders = RemoteData.Loading
    }

JSON 请注意，“数据”数组中没有我可以直接映射到的键。

{
   "fields":[   // Definitions for the "data" key
      {
         "id":"a",
         "label":"S.No.",
         "type":"string"
      },
      {
         "id":"b",
         "label":"Division\/Seat No.",
         "type":"string"
      },....
    ],
   "data":[      <------- Leaders
      [
         1,
         3,
         "Smt.  Sonia  Gandhi",      <------- Name
         15,
         12,
         "Uttar Pradesh",      <------- State
         "Rae Barelii",
         20,      <------- Total Sessions (Attendance)
         9      <------- Sessions Attended (Attendance)
      ],
      [
         2,
         15,
         "Shri  Dayanidhi  Maran",      <------- Name
         15,
         12,
         "Tamil Nadu",      <------- State
         "Chennai Central",
         20,      <------- Total Sessions (Attendance)
         7      <------- Sessions Attended (Attendance)
      ],
      [
         3,
         16,
         "Shri  A.  Raja",      <------- Name
         15,
         12,
         "Tamil Nadu ",      <------- State
         "Nilgiris",
         20,      <------- Total Sessions (Attendance)
         16      <------- Sessions Attended (Attendance)
      ],.....
    ]
}

更新的解决方案

leadersDecoder : Decode.Decoder (List Leader)
leadersDecoder =
    Decode.at [ "data" ] (Decode.list leaderDecoder)


leaderDecoder : Decode.Decoder Leader
leaderDecoder =
    let
        sessionsAttendedDecoder =
            Decode.index 7 Decode.float
                |> Decode.andThen (\total -> attendanceDecoder
                |> Decode.map (\attended -> (attended / total) * 100))
    in
        Decode.map3 Leader
            sessionsAttendedDecoder
            (Decode.index 2 Decode.string)
            (Decode.index 5 Decode.string)

attendanceDecoder : Decode.Decoder Float
attendanceDecoder =
    (Decode.oneOf
        [ Decode.index 8 Decode.float
        , Decode.succeed 0
        ]
    )

Answer 1

Json.Decode.index 可用于从具有指定解码器的数组中提取特定索引。将其与andThen 和map 结合起来进行基于多个字段的考勤计算：

import Json.Decode exposing (..)

leaderDecoder : Decoder Leader
leaderDecoder =
    let
        sessionsAttendedDecoder =
            index 7 float
                |> andThen (\total -> index 8 float
                |> map (\attended -> (attended / total) * 100))
    in
        map3 Leader
            sessionsAttendedDecoder
            (index 2 string)
            (index 5 string)