格式化单元格时非常慢的 VBA 代码

Question

尝试格式化工作簿中的 2 列时，宏的执行速度非常慢。要格式化大约 4000 行，需要 10 多分钟。

日期是从将它们存储为字符串的外部源填充的。

注释代码时，它会在 60 秒内加载。

代码

'Discover last row of data
    RowsToProcess = Range("A" & Rows.Count).End(xlUp).Row

    For i = 6 To RowsToProcess
    Worksheets("Data").Range("B" & i).Select
    Selection.NumberFormat = "dd/mm/yy;;"
    Selection.Value = CDate(Selection.Value)

    Worksheets("Data").Range("C" & i).Select
    Selection.NumberFormat = "dd/mm/yy;;"
    Selection.Value = CDate(Selection.Value)

    Next i

下面的代码也没有按要求的格式格式化单元格。

Worksheets("Data).Columns("C").NumberFormat = dd/mm/yy;;"

Answer 1

@aelgoa 链接到的帖子是正确的。当用于加速代码的标准 Application.ScreenUpdating 选项不够用时，我会转向 Variant 数组。

（如果您想了解我如何使用 Application.ScreenUpdating 等，包裹在 GoFast 函数中，请在此处查看我的答案：VBA code optimization）

下面的脚本是这样工作的：

1. 将 B 列和 C 列中定义的 Range 加载到 Variant 数组中
2. 在那里应用CDate 逻辑（而不是每次都访问Sheet）
3. 将CDate-modified 数组写入Sheet

但有一个警告——我在上面的评论中关于区分 mm/dd 和 dd/mm 的问题（比如 2014 年 5 月 6 日与 2014 年 6 月 5 日）仍然存在。我将根据您的想法修改下面的代码。谢谢！

Option Explicit
Sub ProcessDates()

Dim AryColBandC As Variant
Dim DateFormatB As Date, DateFormatC As Date
Dim RngColBandC As Range
Dim LastRow As Long, Counter As Long
Dim MySheet As Worksheet

'set references up-front
Set MySheet = ThisWorkbook.Worksheets("Sheet1")
With MySheet
    LastRow = .Range("A" & .Rows.Count).End(xlUp).Row
    Set RngColBandC = .Range(.Cells(6, 2), .Cells(LastRow, 3))
End With

'load the B-C column range into a variant array
AryColBandC = RngColBandC

'loop through the variant array, applying the date
'conversion to each entry in the array and writing back
For Counter = LBound(AryColBandC) To UBound(AryColBandC)
    DateFormatB = CDate(AryColBandC(Counter, 1)) '<~ temporarily store
    DateFormatC = CDate(AryColBandC(Counter, 2)) '<~ dates here

    AryColBandC(Counter, 1) = DateFormatB
    AryColBandC(Counter, 2) = DateFormatC
Next Counter

'write the results out to the sheet
For Counter = LBound(AryColBandC) To UBound(AryColBandC)
    MySheet.Cells(5 + Counter, 2) = AryColBandC(Counter, 1)
    MySheet.Cells(5 + Counter, 3) = AryColBandC(Counter, 2)
Next Counter

End Sub