如何使用传感器从另一个通道创建通道？

Question

我想从另一个只过滤特定消息的频道创建一个clojure.core.async 频道。因此，我找到了一个名为 filter<.> 的函数

=> (def c1 (chan))
=> (def c2 (filter< even? c1))
=> (put! c1 1)
=> (put! c1 2)
=> (<!! c2)
2

但是该函数及其朋友被标记为已弃用：

已弃用 - 此功能将被删除。改用换能器

有一些方法可以使用带有传感器的通道，例如带有xform 参数的chan。如何使用传感器从现有通道构建新通道？

Answer 1

我对此进行了一些研究，发现了一些有趣的文章（first 和 second），然后使用 pipeline 得到了一些工作

(require '[clojure.core.async :as async :refer [chan <!! pipeline put!]])
(def c1 (chan))
(def c2 (chan))

(pipeline 4 c2 (filter even?) c1)

(put! c1 1)
(put! c1 2)
(<!! c2)
;;=> 2

我链接的第二篇文章通过管道函数周围的一些辅助函数使这更清晰：

(defn ncpus []
  (.availableProcessors (Runtime/getRuntime)))

(defn parallelism []
  (+ (ncpus) 1))

(defn add-transducer
  [in xf]
  (let [out (chan (buffer 16))]
    (pipeline (parallelism) out xf in)
    out))

然后您可以简单地将频道与

(def c1 (chan))
(def c2 (add-transducer c1 (filter even?))

要完成答案，您发现自己可以以类似的方式使用管道：

(defn pipe-trans
  [ci xf]
  (let [co (chan 1 xf)]
    (pipe ci co)
    co))
(def c1 (chan))
(def c2 (pipe-trans c1 (filter even?)))