在 Clojure 的目录中列出文件

Question

如何从 Clojure 中特定目录中的所有文件创建一个列表？我必须求助于调用 Java 还是 Clojure 可以本地处理？

Answer 1

使用file-seq 函数。

用法示例：

(def directory (clojure.java.io/file "/path/to/directory"))
(def files (file-seq directory))
(take 10 files)

Answer 2

Clojure 旨在支持 Java 平台，这是 Clojure 不提供自己的 API 的一个领域。这意味着您可能必须深入研究 Java，但您必须使用的类完全可以直接从 Clojure 中使用。

您应该在 javadocs 中阅读的一类是java.io.File，它代表一个文件路径。

http://docs.oracle.com/javase/6/docs/api/java/io/File.html

.listFiles 实例方法返回一个包含File 对象的数组（您可以将其用作序列）——一个对应于File 实例标识的目录中的每个条目。还有其他有用的方法可以确定File 是否存在、是否为目录等等。

示例

(ns my-file-utils
  (:import java.io.File))

(defn my-ls [d]
  (println "Files in " (.getName d))
  (doseq [f (.listFiles d)]
    (if (.isDirectory f)
      (print "d ")
      (print "- "))
    (println (.getName f))))

;; Usage: (my-ls (File. "."))

构造文件对象

File 的构造函数有时使用起来有点不方便（尤其是在一次合并多个路径段时），在这种情况下，Clojure 提供了一个有用的辅助函数：clojure.java.io/file。作为它的参数，它接受路径段作为字符串或文件。段与平台的正确路径分隔符连接。

http://clojuredocs.org/clojure_core/clojure.java.io/file

注意：Clojure 还提供了 file-seq 函数，该函数通过从给定文件开始的文件层次结构返回前序遍历（作为 seq）。

Answer 3

还可以查看fs library。

如果您只需要目录中的文件列表，则可能不值得引入额外的依赖项，但那里有许多有用的实用功能，例如：

• 创建目录结构
• 复制、删除、移动
• 检查和更改权限
• 分割和规范化路径
• 创建临时文件和目录
• 通配符
• 使用 zip 和 tar 文件

Answer 4

通常，当我们说要列出目录时，我们的意思是要获取文件名或路径，所以->

列出目录的最简单方法：

(seq (.list (clojure.java.io/file ".")))

如果你想递归列出它，那么：

(map #(.getPath %)
    (file-seq (clojure.java.io/file ".")))

Answer 5

(use 'clojure.java.io)
(-> "/tmp" file .listFiles)

后一个表达式是从方法 listFiles 返回的文件对象数组，调用从路径“/tmp”创建的文件对象。这是一种奇特的写法：

(.listFiles (file "/tmp"))

Answer 6

要使修改后的代码与原始示例代码的功能相匹配，您应该添加获取文件名的调用，如下所示。

(def directory (clojure.java.io/file "/path/to/directory"))
(def files 
    (for [file (file-seq directory)] (.getName file)))
(take 10 files)

Answer 7

一个用于列出目录中文件的宏 - 递归地或仅在父目录中。它还可以搜索具有特定结尾扩展名的文件。

    ;; lists all the files recursively inside the directory passed as d like "."
(defmacro my-rec-list
  "generate the recursive list" {:added "1.0"}
  [d str rec]
  `(->> ~d
       clojure.java.io/file
       ~(if (= rec "rec")
          `file-seq
          `(.listFiles)) 
       ~(cond 
          (= str "file")  `(filter #(.isFile %))
          (= str "dir")   `(filter #(.isDirectory %))
          :always         `(filter #(.matches (.getPathMatcher 
                          (java.nio.file.FileSystems/getDefault)
                          ~str) (.getFileName (.toPath %)))))
       (mapv #(.getAbsolutePath %))))


(defn my-rec-ls-file 
  "generate the recursive list for only files in a directory"
  [d ] 
  (my-rec-list d "file" "rec"))
(defn my-rec-ls-dir 
  "generate the recursive list for only directory"
  [d ] 
  (my-rec-list d "dir" "rec"))
(defn my-rec-ls-jpg 
  "generate the recursive list for files and directory"
  [d ] 
  (my-rec-list d "glob:*.jpg" "rec"))
(defn my-ls-file 
  "generate the recursive list for only files in a directory"
  [d ] 
  (my-rec-list d "file" "norec"))
(defn my-ls-dir 
  "generate the recursive list for only directory"
  [d ] 
  (my-rec-list d "dir" "norec"))
(defn my-ls-jpg 
  "generate the recursive list for files and directory"
  [d ] 
  (my-rec-list d "glob:*.jpg" "norec"))

它导致了不同的函数，可以用目录调用来获取文件列表、目录或匹配的扩展文件 - 递归或非递归。 例子是 -

(def directory (clojure.java.io/file "/Path/to/Directory"))
(my-rec-ls-jpg directory) ;; find all jpg file recessively in directory
(my-ls-jpg directory) ;; find jpg file in current directory