F# 泛型/函数重载语法答案

【问题标题】：F# generics / function overloading syntaxF# 泛型/函数重载语法
【发布时间】：2016-05-28 15:19:50
【问题描述】：

我很困惑如何在没有像 ('a -> 'a) 这样的显式类型声明的情况下将函数标记为泛型

let add a b = a + b

这给了我们

val add : a:int -> b:int -> int

但是我们可以立即调用

add "Hello " "World!"

现在 add 的值为

val add : a:string -> b:string -> string
val it : string = "Hello World!"

如果我们然后调用

add 2 3 // then we get
error: This expression was expected to have type string but here has type int

我如何确保函数适用于所有定义了函数(+) 的类型

【问题讨论】：

我想这是重复的；如果以前没有被问过，我会感到非常惊讶。但这是对问题的一个很好的解释。

标签： function generics types f#

【解决方案1】：

这是 F# 在壁橱里的尴尬骨架。

试试这个：

> let mapPair f (x,y) = (f x, f y)
val mapPair : f:('a -> 'b) -> x:'a * y:'a -> 'b * 'b

完全通用！显然，函数应用程序和元组可以工作。

现在试试这个：

> let makeList a b = [a;b]
val makeList : a:'a -> b:'a -> 'a list

嗯，也是通用的。这个怎么样：

> let makeList a b = [a + b]
val makeList : a:int -> b:int -> int list

啊哈，只要我有一个(+)，它就会因为某种原因变成int。
让我们继续玩吧：

> let inline makeList a b = [a + b]
val inline makeList :
  a: ^a -> b: ^b ->  ^c list
    when ( ^a or  ^b) : (static member ( + ) :  ^a *  ^b ->  ^c)

嗯，有趣。事实证明，如果我创建函数 inline，那么 F# 确实认为它是通用的，但它也给了它这个奇怪的 when 子句，而我的通用参数有这个奇怪的 ^ 符号通常的刻度。
这种奇怪的语法被称为“静态解析类型参数”（请参阅here 以获得一些连贯的解释），基本思想是函数(+) 要求其参数定义为static member (+)。让我们验证一下：

> let x = 0 :> obj
  let y = 0 :> obj
  let z = x + y
Script1.fsx(14,13): error FS0001: The type 'obj' does not support the operator '+'

> type My() =
     static member (+)( a:My, b:My ) = My()
  let x = My()
  let y = My()
  let z = x + y
val x : My
val y : My
val z : My

现在，问题在于 CLR 不支持这种泛型参数（即“任何类型，只要它有这样那样的成员”），所以 F# 不得不伪造它并在编译时解决这些调用。但正因为如此，任何使用此特性的方法都无法编译为真正的通用 IL 方法，因此必须进行单态化（由 inline 启用）。

但是，要求每个使用算术运算符的函数都声明为inline 会很不方便，不是吗？因此，F# 又做了一个额外的步骤，并尝试根据它们稍后在代码中的实例化方式来修复这些静态解析的泛型参数。这就是为什么你的函数一旦与string 一起使用就会变成string->string->string。

但是，如果您将函数标记为inline，F# 就不必修复参数，因为它不必将函数编译为 IL，因此您的参数保持不变：

> let inline add a b = a + b
val inline add :
   a: ^a -> b: ^b ->  ^c
      when ( ^a or  ^b) : (static member ( + ) :  ^a *  ^b ->  ^c)

【讨论】：

“这是 F# 在壁橱里的尴尬骨架。” ——只有一个？
我确定有几个，但我想不起来。

【解决方案2】：

如果我理解正确，请使用 inline：

let inline add a b = a + b

add 2 3 |> printfn "%A"
add "Hello " "World!" |> printfn "%A"

打印：

5
"Hello World!"

链接：http://ideone.com/awsYNI

【讨论】：

【解决方案3】：

设为inline

let inline add a b = a + b
(*
val inline add :
  a: ^a -> b: ^b ->  ^c
    when ( ^a or  ^b) : (static member ( + ) :  ^a *  ^b ->  ^c)
*)
add "Hello " "World!"
// val it : string = "Hello World!"
add 2 3
// val it : int = 5

【讨论】：