将 sub 导入 perl 模块包

Question

来自 Python 和 Java 背景，这让我有点困惑。我有以下文件：

常量.pm

Utils.pl

Main.pl

Constants.pm 有我想与 Main.pl 和 Utils.pl 共享的全局变量。

Utils.pl 有我想与 Constants.pm 和 Main.pl

共享的辅助子程序

#################### Constants.pm
package Constants;
require "Utils.pl";
use Exporter;
our @ISA = 'Exporter';

my %config = parseConfigFile("File.properties");

our @EXPORT = qw($var1 $var2 $var3);
our ($var1, $var2, $var3);

$var1 = $config{var1};
$var2 = $config{var2};
$var3 = $config{var3};


#################### Utils.pl
package Utils;
use Constants;

sub parseConfigFile {};
sub someSub {};

#################### Main.pl
use Constants;
require "Utils.pl"

my $var = someSub($var1);

当我运行 Main.pl 我得到 someSub is undefined 错误

请帮忙，谢谢！

编辑：我没有尝试过@ikegami 的答案，而是将常量中的所有内容移至 Utils.pm 并通过在 main.pl 中使用“use”导入 Utils

Answer 1

[以下解释适用于问题的原始版本。解决方法是一样的。]

require 只执行一次文件，但您希望相同的 subs 出现在两个包中。简单的解决方案是使用do 而不是require。但是你最终会得到一个糟糕的设计。您最终会得到Utils.pl 创建的变量和子项的多个实例。最好将Utils.pl 转换为适当的模块（如Constants.pm）。

Constants.pm:

package Constants;

use strict;
use warnings;

use Exporter qw( import );
use Utils    qw( parseConfigFile );

our @EXPORT_OK = qw( $var1 $var2 $var3 );

my %config = parseConfigFile("File.properties");
our $var1 = $config{var1};
our $var2 = $config{var2};
our $var3 = $config{var3};

1;

Utils.pm:

package Utils;

use strict;
use warnings;

use Constants qw( ... );
use Exporter  qw( import );

our @EXPORT_OK = qw( parseConfigFile someSub );

sub parseConfigFile { ... }
sub someSub { ... }

1;

main.pl:

#!/usr/bin/perl

use strict;
use warnings;

use Constants qw( $var1 );
use Utils     qw( someSub );

my $var = someSub($var1);

但是哎呀！常量使用 Utils，而 Utils 使用常量，它们都从另一个导入。那是个问题。你可以work around it，但parseConfigFile 没有理由加入Utils，所以让我们完全避免这个问题。

Constants.pm:

package Constants;

use strict;
use warnings;

use Exporter qw( import );

our @EXPORT_OK = qw( $var1 $var2 $var3 );

sub parseConfigFile { ... }

my %config = parseConfigFile("File.properties");
our $var1 = $config{var1};
our $var2 = $config{var2};
our $var3 = $config{var3};

1;

Utils.pm:

package Utils;

use strict;
use warnings;

use Constants qw( ... );
use Exporter  qw( import );

our @EXPORT_OK = qw( someSub );

sub someSub { ... }

1;

（我使用@EXPORT_OK 而不是@EXPORT，因为我认为明确命名您的导入是个好主意。）