在 Excel 中使用 QueryTables 导入带有引号的换行符的 csv

Question

我编写了一个 Visual Basic 宏来将一个 csv 文件加载到我经常使用的 Excel 中。

不幸的是，如果 csv 文件包含带引号的换行符，则结果与直接使用 excel 打开 csv 文件时得到的结果不同。与通常的导入工具不同，QueryTables.add() 假定它遇到的任何换行符（无论是否引用）都是行尾。

有没有办法解决这个问题？我更喜欢不涉及预先修改传入的 csv 文件以删除换行符的解决方案，但我也愿意接受这方面的建议。不过，我确实希望在生成的 excel 文件单元格中有换行符。

我的宏的相关部分：

Sub LoadMyFile()
    ' Query the table of interest
    With ActiveSheet.QueryTables.Add(Connection:="TEXT;" _
      & ThisWorkbook.Path & "\" & Range("A1").Value & ".csv", _
      Destination:=Range("$A$2"))
        .Name = ActiveSheet.Name
        .FieldNames = True
        .RowNumbers = False
        .FillAdjacentFormulas = False
        .PreserveFormatting = True
        .RefreshOnFileOpen = False
        .RefreshStyle = xlOverwriteCells
        .SavePassword = False
        .SaveData = True
        .AdjustColumnWidth = True
        .RefreshPeriod = 0
        .TextFilePromptOnRefresh = False
        .TextFilePlatform = 437
        .TextFileStartRow = 1
        .TextFileParseType = xlDelimited
        .TextFileTextQualifier = xlTextQualifierDoubleQuote
        .TextFileConsecutiveDelimiter = False
        .TextFileTabDelimiter = False
        .TextFileSemicolonDelimiter = False
        .TextFileCommaDelimiter = True
        .TextFileSpaceDelimiter = False
        .TextFileColumnDataTypes = Array(1, 1, 1, 1, 1)
        .TextFileTrailingMinusNumbers = True
        .Refresh BackgroundQuery:=False
    End With
End Sub

这是一个带有引号的换行符示例 csv 文件

"firstCol","secondCol"
"name1","data
one"
"name 
2","data two"

宏从单元格 A1 读取文件名（减去 .csv 扩展名），并假定 csv 文件与包含宏的 excel 文件位于同一目录中。

我在 Windows 7 机器上使用 32 位 Office Professional 2010。

Answer 1

此类 CSV 文件（数据点中的换行符）的导入仅适用于 Workbooks。打开且仅适用于区域设置格式（分隔符、文本分隔符）的 CSV，使用 Excel。

Set wb = Workbooks.Open(Filename:="C:\Users\axel\Desktop\test.csv", Local:=True)

aData = wb.Worksheets(1).UsedRange.Value
lRows = UBound(aData, 1)
lCols = UBound(aData, 2)

With ActiveSheet
 .Range(.Cells(1, 1), .Cells(lRows, lCols)).Value = aData
End With

wb.Close

问候

阿克塞尔

Answer 2

编辑：之前提供的代码实际上是根据您提供的具体示例设计的，源 CSV 中有 2 列和相对较少的数据。我已经查看了下面的代码以适应其他可能的场景 - 还包括一些运行时效率的优化。

请注意，我不习惯使用与我在这里依赖的 Open 方法相关的搜索工具，而且我仍然对它们在某些情况下的实际工作方式存在一些疑虑，但是在运行了几次测试之后代码看起来工作得很好。

Sub csvImportbis()

    Dim s As String
    Dim i As Long
    Dim j As Long
    Dim a() As String

    myfile = FreeFile
    i = 1
    j = 1

    'ENTER YOUR PATH/FILE NAME HERE
    Open "YOUR_PATH/FILENAME" For Input As #myfile

        Do Until EOF(myfile)

            Do
                Input #myfile, s
                cur = Seek(myfile)
                Seek myfile, cur - 1
                i = i + 1
            Loop While input(1, #myfile) <> vbLf

            ReDim a(1 To i - 1, 1 To 10000)

            i = 1

            Seek #myfile, 1

            Do Until EOF(myfile)

                Input #myfile, a(i, j)
                i = i + 1

                If i > UBound(a, 1) Then
                    i = 1
                    j = j + 1
                End If

                If j > UBound(a, 2) Then
                    ReDim Preserve a(1 To UBound(a, 1), 1 To UBound(a, 2) + 10000)
                End If

            Loop

        Loop

    Close #myfile

    sup = j

    ReDim Preserve a(1 To UBound(a, 1), 1 To sup)

    'QUALIFY THE RANGE WITH YOUR WORKBOOK & WORKSHEET REFERENCES
    Range("A1").Resize(sup, UBound(a, 1)) = WorksheetFunction.Transpose(a)

End Sub