通过反射获取其 getter 具有可选值的属性的值

Question

我正在检索控件的几个属性。以下是我用来检索属性的方式（使用 PropertyInfo 类型的 pinfo）：

value = pinfo.GetValue(obj, nothing)

效果很好，但现在我面临一个具有可选值的属性，我收到一条错误消息，告诉我参数的数量不正确。所以我用这个改变了我的代码：

Dim index As Object() = {Nothing}
value = pinfo.GetValue(obj, index)

此时，我没有收到任何错误消息，但是这段代码没有检索到好的值。仅当我将 Nothing 替换为属性访问器提供的默认值时才有效...

但是我事先不知道这个默认值是什么！而且这段代码是在一个函数中，它检索没有可选值的属性，所以我不能更改代码，特别是针对一种情况或另一种情况..

有什么想法吗？我正在开发 .NET 2.0

---

编辑：关于导致问题的案例的更多精确度

这是导致问题的属性示例：

ReadOnly Property Foo(Optional ByVal Number As Integer = -1) As String
    Get
        If Number = -1 Then
            Return "Your number is the default number: " & Number
        Else
            Return "Your number is " & Number
        End If
    End Get
End Property

有了这种属性，上面的代码都没有检索到好的字符串。

我最好的猜测是尝试一般用途的第一个代码，捕获适当的异常，然后动态检索 参数的默认值（在这种情况下为数字）和 输入，这样我就可以用这个默认值调用getValue。

那么，如何获取可选参数的默认值？

Answer 1

这适用于可选参数：

ReadOnly Property Foo(Optional name As String = Nothing) As String
    Get
        If name Is Nothing Then
            Return "Hello World"
        Else
            Return "Hello " & name
        End If
    End Get
End Property


Dim pinfo As Reflection.PropertyInfo = Me.GetType().GetProperty("Foo")
Dim value As Object = pinfo.GetValue(Me, New Object() {"Tim"})  ' Hello Tim '
value = pinfo.GetValue(Me, New Object(){Nothing})               ' Hello World '

编辑：根据您对整数不起作用的评论，我还不知道如何在属性中获取可选参数的默认值。如果你知道它，你可以很容易地通过它，否则会发生以下情况（注意 Int32.MinValue 作为默认值而不是 0）：

ReadOnly Property Foo(Optional age As Int32 = Int32.MinValue) As String
    Get
        If age = Int32.MinValue Then
            Return "I don't know how old i am"
        Else
            Return String.Format("I am {0} years old", age)
        End If
    End Get
End Property

Dim pinfo As Reflection.PropertyInfo = Me.GetType.GetProperty("Foo")
Dim value As Object = pinfo.GetValue(Me, New Object() {38})  ' I am 38 years old '
value = pinfo.GetValue(Me, New Object() {Nothing})           ' I am 0 years old '
value = pinfo.GetValue(Me, New Object() {Int32.MinValue})    ' I don't know how old i am '

---

Edit2：感谢@Rup，现在我知道GetIndexParameters 是缺失的部分。所以以下应该适用于任何类型的参数。

Dim pinfo As Reflection.PropertyInfo = Me.GetType.GetProperty("Foo")
Dim parameters() As Reflection.ParameterInfo = pinfo.GetIndexParameters()
Dim params(parameters.Length - 1) As Object
For i As Int32 = 0 To parameters.Length - 1
    Dim paramInfo As Reflection.ParameterInfo = parameters(i)
    If paramInfo.IsOptional Then
        params(i) = paramInfo.DefaultValue
    Else
        If paramInfo.ParameterType.IsValueType Then
            params(i) = Activator.CreateInstance(paramInfo.ParameterType)
        Else
            params(i) = Nothing
        End If
    End If
Next
Dim value As Object = pinfo.GetValue(Me, params)

Answer 2

试试下面的例子。验证对象是否为空，然后使用 Activator 激活它。 以下程序是用 C# 编写的。

class Program
{
    static void Main(string[] args)
    {
        Test testObj = null;
        testObj = testObj ?? Activator.CreateInstance<Test>();
        var ty = testObj.GetType().GetProperty("MyProperty").GetValue(testObj, null);

    }
}
public class Test
{
    public Test2 MyProperty { get; set; }
}
public class Test2
{
    public int Prty { get; set; }
}