如何在稍后评估它们时绑定函数

Question

我正在学习 Clojure 以将其与 Quil 一起使用来制作生成艺术，我想尝试更多地了解 let 函数和 reader 宏。

我尝试从文档中阅读阅读器宏，但找不到明确的答案。

我目前有这段代码：

(let [dabs (take 10 (repeatedly #(make-watercolor 
                                   (mkpt 
                                     (randomNormal 0.1 0.9) 
                                     (randomNormal 0.1 0.9))
                                   (w (randomNormal 0.4 0.7)))))]
    (draw-multiple-watercolor dabs 3))

这很丑陋，而且不可读。 我想精简重复的函数，将其拆分成更小的部分，但由于这些部分将被多次评估并且内部具有随机性，我无法将它们的结果存储在变量中并使用它，而是需要在需要时评估它们。

我的问题是：有没有办法做这样的事情

(let [randCoord (randomNormal 0.1 0.9) ;This..
      randPoint (mkpt randCoord randCoord) ;..and this doesn't should be evaluated here, but on the repeatedly function calls
      dabs (take 10 (repeatedly #(make-watercolor 
                                   randPoint ;Evaluation here
                                   (w (randomNormal 0.4 0.7)))))]
    (draw-multiple-watercolor dabs 3))

Answer 1

一种选择是使用与传递给 repeatedly 的函数相同的方法：只需将表达式包装在不带参数的函数中（或仅带您想要更改的参数），然后它们将每次调用函数时都会进行评估。

(let [rand-coord (fn [] (randomNormal 0.1 0.9)) ;; or #(randomNormal 0.1 0.9)
      make-dab #(make-watercolor (mkpt (rand-coord) (rand-coord))
                                 (w (randomNormal 0.4 0.7)))
      dabs (take 10 (repeatedly make-dab))]
  (draw-multiple-watercolor dabs 3))

还可以查看 letfn 以在非顶级/命名空间范围内定义函数。

您可能还会发现 threading 宏，例如 ->、->>、as->、some->、cond-> 等，可以使某些代码更具可读性。例如，如果您将draw-multiple-watercolor 更改为采用它的 dabs last 序列（这对于在 Clojure 中对序列进行操作的函数来说是相当普遍的做法），那么您可以执行以下操作：

(let [rand-coord (fn [] (randomNormal 0.1 0.9)) ;; or #(randomNormal 0.1 0.9)
      make-dab #(make-watercolor (mkpt (rand-coord) (rand-coord))
                                 (w (randomNormal 0.4 0.7)))]
  (->> make-dab
       (repeatedly 10) ;; note: repeatedly can take a # of iterations
       (draw-multiple-watercolor 3)))